Using LIKE in sp_executesql

Question

SET @whereCond = @whereCond + ' AND name LIKE ''%'' + @name + ''%'''

Is there something wrong here? After I generate where condition, I execute it with sp_executesql, but I did get anything. When I SELECT the same thing without sp, it's ok.

How to use LIKE in sp_executesql? Can you bring some examples, please?

Thank you.

UPDATE

declare @name nvarchar(50)

set @name = 'a'

SELECT *
    FROM Tbl_Persons WHERE 1 = 1  AND lastname LIKE '%a%' 

exec sp_executesql 
  N'SELECT *
    FROM Tbl_Persons WHERE 1 = 1  AND lastname LIKE ''%@name%''', 
  N'@name nvarchar(50)',
  @name=@name

First query returns values, second one doesn't return anything.

What's the difference?

Ultan

Answer 1

The following works for me

declare @name varchar(50)

set @name = 'WAITFOR'


exec sp_executesql 
  N'select * from sys.messages WHERE text  LIKE ''%'' + @name + ''%''', 
  N'@name varchar(50)',
  @name=@name

I think the problem must lie elsewhere.

Edit: Following your update you need to use

exec sp_executesql 
  N'SET @name = ''%'' + @name + ''%'';
    SELECT *
    FROM Tbl_Persons WHERE 1 = 1  AND lastname LIKE @name', 
  N'@name nvarchar(50)',
  @name=@name

As it stands you are searching for text containing the actual substring @name

Missend

I've checked your script and it's working, but mine doesn't work. I've edited my question. thank you. – Ultan

why is this assignment '@name=@name' required here, Isn't just enough to pass @name ? – Septempartite

@Septempartite The first name is the parameter used in the query expression and the second name is the variable containing the value (that should substitute the parameter). I prefer to give them different names though. – Sweepings

This doesn't work when @name contains apostrophe character (single quotation mark) , for example D'souza – Telic

@Telic - yes it does. This isn't creating the SQL string itself with concatenation – Missend

See for example declare @name varchar(50) set @name = 'it''s' exec sp_executesql N'select * from sys.messages WHERE text LIKE ''%'' + @name + ''%''', N'@name varchar(50)', @name=@name which returns these results i.sstatic.net/l8XRv.png – Missend

I was missing escape character. thank you – Telic