How to set the font size in Emacs?

D

17

393

I also want to save the font size in my .emacs file.

Dorsman answered 17/11, 2008 at 1:0 Comment(4)

see also: #2092381 – Opec 25/3, 2011 at 13:41

This is the simplest answer that worked for me https://mcmap.net/q/87875/-how-do-i-change-emacs-39-default-font-size-and-font-type – Orban 18/12, 2013 at 18:24

Novice, use .emacs.d/init.el instead which is better (cleaner and better version control) – Polanco 8/4, 2016 at 8:35

See also emacs.stackexchange.com/a/10439/5165 – Ovular 7/10, 2021 at 19:38

L

464

(set-face-attribute 'default nil :height 100)

The value is in 1/10pt, so 100 will give you 10pt, etc.

Lodgment answered 17/11, 2008 at 17:49 Comment(6)

I'm trying to do this, but in Emacs 23.1.1 the auto-complete will only show the options

set-face-background set-face-font set-face-inverse-video-p set-face-underline set-face-background-pixmap set-face-foreground set-face-stipple set-face-underline-p

. – Midwife 24/1, 2013 at 12:38

@TomBrito Which autocomplete? In my Emacs, set-face-attribute is indeed missing from M-x (execute-extended-command), but it is present in M-: (eval-expression) and C-h f (describe-function). M-: is probably what you want, if you don't want to put this in your .emacs file. – Hypertrophy 9/5, 2013 at 14:20

@RoryO'Kane Why are some commands not available via M-x? Noob question, I'm sure, but I'm not familiar with how emacs "works" at a low-level – Coronary 6/3, 2015 at 20:53

@DavidS Good question. I wrote up an answer at “Why are some Emacs functions not available via M-x?”. Researching the answer turned out to be educational. – Hypertrophy 22/3, 2015 at 21:5

This solution doesn't work though when you have customized some faces, e.g. to have a distinct font, slant, etc. They would be left with the old size, and you gotta set them individually. – Ory 28/1, 2019 at 8:22

Confirmed does not work in GNU Emacs 25.2.2 for my init.el file at least. I love having a beautiful night of coding on emacs, then spending 1+ hr trying to figure out how to decrease the font size. – Collusion 4/4, 2022 at 5:53

R

417

From Emacswiki, GNU Emacs 23 has a built-in key combination:

C-xC-+ and C-xC-- to increase or decrease the buffer text size

Reliant answered 4/5, 2010 at 21:6 Comment(6)

or `C-x C-=’ and ‘C-x C--’ – Mumble 19/3, 2012 at 15:37

This is local to that particular buffer. So when you switch to other files you're editing, they will not see the effect of this change. Also when you close and reopen the buffer (or even restart Emacs), they'll be at the old default size. This may be what you want; I'm just stating this for completeness. – Lipsey 22/5, 2012 at 4:43

The OP wants to save config in .emacs, and this doesn't. – Domingadomingo 5/3, 2015 at 16:42

works in spacemacs UI (in macos), to set in init.el - https://mcmap.net/q/86669/-how-to-set-the-font-size-in-emacs – Sacramental 1/10, 2018 at 5:26

In elisp, these keys run the text-scale-adjust, text-scale-increase, and text-scale-mode functions in face-remap.el – Broida 6/7, 2021 at 1:33

If you want C-x C-+ to increase font size in all buffers, check this post – Metachromatism 12/2, 2022 at 12:43

T

80

Press Shift and the first mouse button. You can change the font size in the following way: This website has more detail.

Tartuffery answered 17/11, 2008 at 1:7 Comment(2)

@AndrewLarned To make the change permanent, you'd make the change in your .emacs file. (See Chris Conway's answer for an example of what he has in his .emacs file.) – Talipes 24/5, 2012 at 3:16

Is there any way to control how much it increases or decreases the font when doing this? – Quadrinomial 13/11, 2013 at 12:35

A

44

M-x customize-face RET default will allow you to set the face default face, on which all other faces base on. There you can set the font-size.

Here is what is in my .emacs. actually, color-theme will set the basics, then my custom face setting will override some stuff. the custom-set-faces is written by emacs's customize-face mechanism:

;; my colour theme is whateveryouwant :)
(require 'color-theme)
(color-theme-initialize)
(color-theme-whateveryouwant)

(custom-set-faces
  ;; custom-set-faces was added by Custom.
  ;; If you edit it by hand, you could mess it up, so be careful.
  ;; Your init file should contain only one such instance.
  ;; If there is more than one, they won't work right.
 '(default ((t (:stipple nil :background "white" :foreground "black" :inverse-video nil :box nil :strike-through nil :overline nil :underline nil :slant normal :weight normal :height 98 :width normal :foundry "unknown" :family "DejaVu Sans Mono"))))
 '(font-lock-comment-face ((t (:foreground "darkorange4"))))
 '(font-lock-function-name-face ((t (:foreground "navy"))))
 '(font-lock-keyword-face ((t (:foreground "red4"))))
 '(font-lock-type-face ((t (:foreground "black"))))
 '(linum ((t (:inherit shadow :background "gray95"))))
 '(mode-line ((t (nil nil nil nil :background "grey90" (:line-width -1 :color nil :style released-button) "black" :box nil :width condensed :foundry "unknown" :family "DejaVu Sans Mono")))))

Anticipate answered 17/11, 2008 at 1:19 Comment(2)

Many advanced emacs users prefer to not use the customize system, as it's error prone and intermingles all customizations. It's better to break your customization up into individual .el files and load them from init.el, and add your mode customizations as elisp code within each one. See huaiyuan's answer above to see how to set font via elisp. – Utmost 19/6, 2013 at 2:28

FWIW, the emacs maintainer (presumably an "advanced" user of emacs) uses the customize system: github.com/jwiegley/dot-emacs/blob/… – Ockham 13/3, 2018 at 17:2

T

41

This is another simple solution. Works in 24 as well

(set-default-font "Monaco 14")

Short cuts:

`C-+` increases font size
`C--` Decreases font size

Trainer answered 24/2, 2014 at 13:39 Comment(2)

set-default-font is now deprecated. Use either (set-frame-font "Monaco 14") or (set-face-attribute 'default nil :height 130) – Metachromatism 12/2, 2022 at 12:4

@Metachromatism Thank you for the warning. Do you know what's the relationship between the size in set-frame-font and in :height? In my Emacs, setting the latter to 93, 94, or 95 has exactly the same effect. – Xyster 2/8, 2022 at 10:55

P

16

Open emacs in X11, goto menu Options, select "set default font ...", change the font size. Select "save options" in the same menu. Done.

Plastometer answered 25/1, 2013 at 11:51 Comment(2)

The changes do not persist if I restart emacs. – Agglutinogen 7/2, 2019 at 2:28

To keep the setting for the next time, make sure you select save options after setting the font – Cocktail 13/4, 2022 at 8:44

C

15

I've got the following in my .emacs:

(defun fontify-frame (frame)
  (set-frame-parameter frame 'font "Monospace-11"))

;; Fontify current frame
(fontify-frame nil)
;; Fontify any future frames
(push 'fontify-frame after-make-frame-functions)

You can subsitute any font of your choosing for "Monospace-11". The set of available options is highly system-dependent. Using M-x set-default-font and looking at the tab-completions will give you some ideas. On my system, with Emacs 23 and anti-aliasing enabled, can choose system fonts by name, e.g., Monospace, Sans Serif, etc.

Compile answered 17/11, 2008 at 2:11 Comment(0)

R

11

zoom.cfg and global-zoom.cfg provide font size change bindings (from EmacsWiki)

C-- or C-mousewheel-up: increases font size.
C-+ or C-mousewheel-down: decreases font size.
C-0 reverts font size to default.

Rosiarosicrucian answered 17/4, 2013 at 8:26 Comment(1)

C-0 is already in good use unfortunately. And the links broke. But great idea! – Nevels 13/9, 2021 at 14:49

I

10

Here's an option for resizing the font heights interactively, one point at a time:

;; font sizes
(global-set-key (kbd "s-=")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (+ old-face-attribute 10)))))

(global-set-key (kbd "s--")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (- old-face-attribute 10)))))

This is preferable when you want to resize text in all buffers. I don't like solutions using text-scale-increase and text-scale-decrease as line numbers in the gutter can get cut off afterwards.

Irv answered 17/7, 2014 at 16:36 Comment(1)

This is perfect! Thank you so much. – Annexation 28/3, 2016 at 19:51

K

9

Firefox and other programs allow you to increase and decrease the font size with C-+ and C--. I set up my .emacs so that I have that same ability by adding these lines of code:

(global-set-key [C-kp-add] 'text-scale-increase)

(global-set-key [C-kp-subtract] 'text-scale-decrease)

Kaisership answered 22/12, 2013 at 14:20 Comment(0)

B

7

Aquamacs:

(set-face-attribute 'default nil :font "Monaco-16" )

From the Emacs Wiki Globally Change the Default Font, it says you can use either of these:

(set-face-attribute 'default nil :font FONT )

(set-frame-font FONT nil t)

Where FONT is something like "Monaco-16", e.g.:

(set-face-attribute 'default nil :font "Monaco-16" )

There was an extra closing parenthesis in the first suggestion on the wiki, which caused an error on startup. I finally noticed the extra closing parenthesis, and I subsequently corrected the suggestion on the wiki. Then both of the suggestions worked for me.

Brunt answered 5/3, 2017 at 7:12 Comment(0)

T

4

It all depends what you mean by change the font size. This EmacsWiki section provides the best and most complete information. It distinguishes the various cases (text scaling, frame font, buffer/frame, etc.): Changing Font Size.

Tolmann answered 17/11, 2011 at 15:54 Comment(0)

C

2

In NTEmacs 23.1, the Options menu has a "Set default font..." option.

Congeries answered 11/4, 2010 at 22:32 Comment(0)

K

2

In AquaMacs CMD + and CMD - adjust the font size for the current buffer.

Kitchens answered 15/4, 2013 at 0:21 Comment(0)

T

2

Here's a snippet that lets you directly specify the global font size using an interactive function:

(defun set-font-size ()
    "Set the font size."
  (interactive)
  (set-face-attribute
   'default nil :height
   (string-to-number
    (read-string "Font size: " (number-to-string (face-attribute 'default :height nil))))))

Trousseau answered 26/4, 2018 at 22:31 Comment(0)

W

1

I you're happy with console emacs (emacs -nw), modern vterm implementations (like gnome-terminal) tend to have better font support. Plus if you get used to that, you can then use tmux, and so working with your full environment on remote servers becomes possible, even without X.

Weal answered 15/8, 2012 at 16:9 Comment(0)

E

1

I use hydra package to control font increase/decrease contiguously by pressing f2 + + + +/f2 - - - -, which means that press f2 once, and then using +/- to control only, and restore default font size by f2 0. Because i have keypad, so I also bind keypad to the font setting.

(defhydra hydra-zoom (global-map "<f2>")
  "zoom"
  ("<kp-add>" text-scale-increase "in")
  ("+" text-scale-increase "in")
  ("-" text-scale-decrease "out")
  ("<kp-subtract>" text-scale-decrease "out")
  ("0" (text-scale-set 0) "reset")
  ("<kp-0>" (text-scale-set 0) "reset"))

And modern editor mouse control functionality supported by below key bindings, press control + mouse wheel to increase/decrease font.

(global-set-key (kbd "<C-wheel-up>") 'text-scale-increase)
(global-set-key (kbd "<C-wheel-down>") 'text-scale-decrease)

Erase answered 17/6, 2015 at 10:41 Comment(2)

The key bindings for the mouse wheel don't work, I have version GNU Emacs 24.3.1 (x86_64-pc-linux-gnu, GTK+ Version 3.10.7) – Mohammedanism 13/11, 2015 at 17:45

Those would be (global-set-key (kbd "<C-mouse-4>") 'text-scale-increase) (global-set-key (kbd "<C-mouse-5>") 'text-scale-decrease) In my version of emacs (25) – Automat 9/3, 2017 at 22:7

Recommended topics

Hot tags