Unity Intersections Mask

Question

Is there any way to detect if an object with a certain amount of vertices hits a plane? If so, I want to draw it in binary (black/white) onto the plane or create a texture with it.

And I also don't care about if this can only be created with raycasts or some tricky physics operations / shaders / etc.. I'm just wondering what mathematical algorithm could create this.

Here is an example of what I'm trying to achieve:

Cheers, Michael

Lawson

Answer 1

Most games will achieve this with specialized shaders:

1. First pass renders a depth map for opaque objects in the scene
2. Second pass uses an intersection shader for transparent object(s)

The intersection shader looks for fragments where depth is equal (or nearly equal) to the depth from the first pass, then colors those fragments differently.

A question on the Game Development Stack Exchange goes into more detail, including screenshots and a WebGL demo.

In your case, this might look like:

1. Render the plane as opaque geometry
2. Render the other objects using intersection shader
   • Fragments that intersect the plane are drawn
   • Fragments that do not intersect the plane are discarded

Whether you are doing this for an entire scene, or just to generate a texture that you can apply to some other object, the shader principles remain the same either way.

Preciosity

Could u maybe give me an example of this shader in unity.. im not that good with shaders? – Lawson

Answer 2

Writing the shader myself I stumbled across this Question so many times because google image search shows it every time.

I might be 4 years to late but for everyone else, I've written a shader that does exactly what's on the picture:

Shader for the Wall (ShaderOne)

Shader "Custom/ShaderOne"
{
    SubShader {
        Tags { "RenderType"="Opaque" "Queue"="Geometry"}
            Pass {
            Stencil {
                Ref 2
                Comp always
                Pass replace 
            }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            struct appdata {
                float4 vertex : POSITION;
            };
            struct v2f {
                float4 pos : SV_POSITION;
            };
            v2f vert(appdata v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                return o;
            }
            half4 frag(v2f i) : SV_Target {
                return half4(0.5,0.5,0.5,1);
            }
            ENDCG
        }
    } 
}

Shader for the Object(s) (ShaderTwo)

Shader "Custom/ShaderTwo"
{
    SubShader {
        Tags {"Queue" = "Transparent" "RenderType"="Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass {

            Stencil {
                Ref 2
                Comp equal
                Pass IncrWrap
                ZFail keep
            }

            ZTest less
            Cull Front
            ZWrite OFF

            CGPROGRAM
            #pragma vertex vert 
            #pragma fragment frag alpha
            struct appdata {
                float4 vertex : POSITION;
            };
            struct v2f {
                float4 pos : SV_POSITION;
            };
            v2f vert(appdata v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                return o;
            }
            half4 frag(v2f i) : SV_Target {
                return half4(0,0,1,0.0);
            }
            ENDCG
        }
   
        Pass {

            Stencil {
                Ref 2
                Comp equal
                Pass keep
                ZFail keep
            }

            ZTest less
            Cull Back
            ZWrite OFF

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            struct appdata {
                float4 vertex : POSITION;
            };
            struct v2f {
                float4 pos : SV_POSITION;
            };
            v2f vert(appdata v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                return o;
            }
            half4 frag(v2f i) : SV_Target {
                return half4(1,0,0,0.5);
            }
            ENDCG
        }
    } 
}

Vorous

Answer 3

You can take a look on a similar thread on unity forum:

The image link: https://forum.unity.com/proxy.php?image=https%3A%2F%2Flh3.googleusercontent.com%2FRnj-LM2i238HSMGSEhRUEn81M7TrdifT6WZziEU2LpwpAYShVkXbdpBImOSc4DSxlsGyaN6eTG1HWP9qKrG7E7StGGMgF4e27bHVLsoWvQXelyPw0fHhZ2fpRPeERg8twaeo3omd3Q%3Dw660-h558-no&hash=41a049afb39e6495d86db0ab14a8e936

The forum thread: https://forum.unity.com/threads/intersection-shader-cull-front-minus-cull-back.536812/

Luiseluiza