Is it possible to use Attributes on Delphi method arguments?

Question

Is this valid code with newer Delphi versions?

// handle HTTP request "example.com/products?ProductID=123"
procedure TMyRESTfulService.HandleRequest([QueryParam] ProductID: string);

In this example, the argument "ProductID" is attributed with [QueryParam]. If this is valid code in Delphi, there must also be a way to write RTTI based code to find the attributed argument type information.

See my previous question Which language elements can be annotated using attributes language feature of Delphi?, which lists some language elements which have reported to work with attributes. Attributes on arguments were missing on this list.

Indissoluble

Unfortunately the documentation is wrong. It says: The following code blocks exemplify the different language constructs that allow annotations. Having announced a complete enumeration of the language constructs, it then gives an incomplete list. – Pocosin

Answer 1

Yes you can:

program Project1;

{$APPTYPE CONSOLE}

uses
  Rtti,
  SysUtils;

type
  QueryParamAttribute = class(TCustomAttribute)
  end;

  TMyRESTfulService = class
    procedure HandleRequest([QueryParam] ProductID: string);
  end;

procedure TMyRESTfulService.HandleRequest(ProductID: string);
begin

end;

var
  ctx: TRttiContext;
  t: TRttiType;
  m: TRttiMethod;
  p: TRttiParameter;
  a: TCustomAttribute;
begin
  try
    t := ctx.GetType(TMyRESTfulService);
    m := t.GetMethod('HandleRequest');
    for p in m.GetParameters do
      for a in p.GetAttributes do
        Writeln('Attribute "', a.ClassName, '" found on parameter "', p.Name, '"');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

Caret

+1 - These attributes are powerful but not well documented :( – Hyde