Adding a new entry to the PATH variable in ZSH

Question

I'm using zsh terminal, and I'm trying to add a new entry (/home/david/pear/bin) to the PATH variable. I don't see a reference to the PATH variable in my ~/.zshrc file, but doing echo $PATH returns:

/usr/lib/lightdm/lightdm:/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin:/usr/games

So I know that the path variable is being set somewhere. Where is the PATH variable set / modified for the zsh terminal?

Draper

In my opinion, PATH should be manipulated in .zshenv, not in .zshrc... – Showing

In case anyone else is curious about @Rmano's pointer on using '.zshenv' (as I was), here's link a detailed discussion. – Milium

Answer 1

Here, add this line to .zshrc:

export PATH=/home/david/pear/bin:$PATH

EDIT: This does work, but ony's answer above is better, as it takes advantage of the structured interface ZSH provides for variables like $PATH. This approach is standard for bash, but as far as I know, there is no reason to use it when ZSH provides better alternatives.

Malikamalin

haha forget it, I though that was only a console command but adding that line to the .zshrc did the trick. Thanks a lot! – Draper

My .zshrc already had a line for export PATH so I replaced it with the modified one. – Hydrogeology

I had to remove the double quotes around the entries i.e. PATH="/home/david/pear/bin:/usr/bin:etc" to PATH=/home/david/pear/bin:/usr/bin:etc for it to stay in zshrc. – Hegelianism

@taco, you can use $HOME – Byron

It will erase all the old PATH, try export PATH=$PATH:/path/to/dir – Ballenger

This appends to my existing PATH, and every time it's run, appends again. How do I set exactly what PATH should be? – Goldshell

You can set PATH directly: export PATH=/some/where:/bin:/usr/bin and so on. Is that what you're asking? The idea is to run the code in this answer in the .zshrc or .profile or something like that at the beginning of each session. – Malikamalin

Just a side note, if your path has a space in it. then you need to wrap your path in double quotes like this: export PATH=$PATH:"/Applications/Android Studio.app/Contents" – Consumer

Answer 2

Actually, using ZSH allows you to use special mapping of environment variables. So you can simply do:

# append
path+=('/home/david/pear/bin')
# or prepend
path=('/home/david/pear/bin' $path)
# export to sub-processes (make it inherited by child processes)
export PATH

For me that's a very neat feature which can be propagated to other variables. Example:

typeset -T LD_LIBRARY_PATH ld_library_path :

Eastwards

Nice answer. In my case, ~/.zshrc is sourced after .profile, and overwrites everything in .profile. Took a while pulling my hair to figure it out. – He

The append case does does not need the parens unless you're appending more than one element. It also often doesn't need the quotes. So the simple, short way to append is – Packard

@SuperUberDuper, you should understand that almost any unix shell simply reads startup files which does almost the same as if you'd type it into shell interactively. Regarding "rc" files you might find interesting answer to this question – Eastwards

It's possible to avoid explicit export with -x and leave only unique values in a variable with -U, colon is assumed by default, so it can be: typeset -TUx PATH path – Dispraise

I see the use of path and PATH, both are separate entities? – Abramabramo

@CousinCocaine, you are right. ZSH variables are case-sensitive. typeset -T allows to tie PATH and path together in a special way that internally ZSH manages array variable path and reflects its contents in PATH as a scalar. – Eastwards

You can even have it as 1-liner: export path=(... $path). – Agrostology

This doesn't work for me on my mac. I use the one liner answer below that updates ~/.zshrc insead. – Fragrance

@KhanhNguyen how can I see when these files are sourced? Is there a cmd? – Bowden

@Timo, in case of zsh you can try something like zsh -x -i -l -c true to see all commands during shell start-up. That -l is to simulate login-like start (as it happens from text VT or over ssh). But you should understand that not always zsh will be started as login (e.g. graphical session) and some other parent process may somehow source .profile before spawning non-login zsh sub-process that inherits environment variables (including PATH) from parent process. – Eastwards

What if i want to use $HOME inside ' '? path +=('$HOME/etc/etc') doesn't seem to work – Chemotaxis

@Rotkiv, that's a bit different question about how single/double quotes are interpreted. I guess zsh expansion covers this. Usually double-quotes allow string interpolation like "$HOME/etc/etc", but single quotes makes it easier to represent text that should not get special treatment. Note that you can always mix in a single argument forms to have something like "$HOME"'/etc/etc' (double + single quotes) or "$HOME"/etc/etc (double quotes + unquoted). P.S. Yes I'm lazy to try find link to good answer on SO :P – Eastwards

On macOS, you can prepend and append to your path variable as described in the post, adding to the .zshrc file. It works without exporting the PATH. – Enrobe

If this append or prepend syntax doesn't work for you, make sure that you are using lower case path. Lower case path is the array. – Gur

Thank you for showing the prepend as well! Didn't see it anywhere else. – Photophore

This does not seem to work with ~. – Glutamate

This didn't work for me even though things looked absolutely fine when I echo $PATH. I had to go back to the "traditional" syntax of something like: export PATH=$ANDROID_HOME/platform-tools:$PATH – Marolda

@MinhNghĩa, ~ is expanded by shell. If you put it in quotes like '~/bin' or "~/bin" it will be literally tilda in your path. E.g. you can write path+=(~/bin) (note no quotes) or similar. If you need to quote something, you still can do it on part like path+=(~/'some path with spaces'). – Eastwards

@Phil, my best guess for your case is that ok result of echo $PATH shows your current shell value for it. Any chance it works if you do export PATH (upper case) to export for sub-process after setting path (lower case)? – Eastwards

Append did not work for me. Old school export did. – Pantsuit

This might have worked in 2013, but it doesn't work in macOS in 2024. – Miley

I've been coming back to this answer since 2013. I mean... I could read the typeset man page to find args 'U' and 'x' but this has been working for over a decade and now I'm old and jaded. So thanks! and I'll see you guys next year. – Taker

Answer 3

You can append to your PATH in a minimal fashion. No need for parentheses unless you're appending more than one element. It also usually doesn't need quotes. So the simple, short way to append is:

path+=/some/new/bin/dir

This lower-case syntax is using path as an array, yet also affects its upper-case partner equivalent, PATH (to which it is "bound" via typeset).

(Notice that no : is needed/wanted as a separator.)

Common interactive usage

Then the common pattern for testing a new script/executable becomes:

path+=$PWD/.
# or
path+=$PWD/bin

Common config usage

You can sprinkle path settings around your .zshrc (as above) and it will naturally lead to the earlier listed settings taking precedence (though you may occasionally still want to use the "prepend" form path=(/some/new/bin/dir $path)).

Related tidbits

Treating path this way (as an array) also means: no need to do a rehash to get the newly pathed commands to be found.

Also take a look at vared path as a dynamic way to edit path (and other things).

You may only be interested in path for this question, but since we're talking about exports and arrays, note that arrays generally cannot be exported.

You can even prevent PATH from taking on duplicate entries (refer to this and this):

typeset -U path

PATH pre-populated

The reason your path already has some entries in it is due to your system shell files setting path for you. This is covered in a couple other posts:

• Why and where the $PATH env variable is set?
• Where is the source of $PATH? I cannot find it in .zshrc

Packard

@andrewlorien I updated the answer with details about the colon separator. – Packard

Note that if there’s a comment after the path, then we do need quotes, like path+='my/path' # for fun. It’s obvious if you have spaces, but not so much if you have comments. – Godson

"(Notice that no : is needed/wanted as a separator.)" This is only true for a lowercase path. A preceding : is required for PATH, as follows in .zshrc PATH+=:/Users/path/to/my/folder – Freedom

I use a lot exec zsh because I work with plugins from oh-my-zsh.Everytime I do exec the path gets bigger. Should I "default" the path from time to time? – Bowden

For ZSH to interpret $PATH as an array and make it unique, I believe the correct way would be typeset -aU path – Dominick

Answer 4

one liner, without opening ~/.zshrc file

echo -n 'export PATH=~/bin:$PATH' >> ~/.zshrc

or

echo -n 'export PATH=$HOME/bin:$PATH' >> ~/.zshrc

To see the effect, do source ~/.zshrc in the same tab or open a new tab

Borges

Worked perfecly on OSX with Zsh shell. – Craggie

Worked like a charm! – Preparedness

Perfect! on MacOS M2 – Tango

Thanks! One line solution seems perfect – Altamirano

Works in Catalina – Faxun

Answer 5

1. Added path to ~/.zshrc

   sudo vi ~/.zshrc

   add new path

   export PATH="$PATH:[NEW_DIRECTORY]/bin"
   

2. Update ~/.zshrc

   Save ~/.zshrc

   source ~/.zshrc

3. Check PATH

   echo $PATH

Dillman

This is the Bash way. – Abramabramo

effective way to do – Calmative

Answer 6

OPTION 1: Add this line to ~/.zshrc:

export "PATH=$HOME/pear/bin:$PATH"

After that you need to run source ~/.zshrc in order your changes to take affect OR close this window and open a new one

OPTION 2: execute it inside the terminal console to add this path only to the current terminal window session. When you close the window/session, it will be lost.

Dusen

Can you elaborate on how this answer is different from the same answer posted 5 years ago? – Godson

in this answer it is not said that you have to add this line of code to the file, if you just run it like that it will change only in the current windows and this is not explain in the original answer – Dusen

add this to file .zshrc without qoutes export PATH=$HOME/pear/bin:$PATH – Corroborate

Answer 7

If you are on macOS (I'm on Monterey 12.3.1), you may have been pulling your hair like I did metaphorically. These instructions above all worked for me within the terminal session, but I could never get it to persist no matter what I did with export. Moreover, I couldn't find the .zshrc anywhere.

Turns out Apple does it differently. The file you need to edit is etc/paths. You can simply sudo nano /etc/paths and add your path in a new line. Then simply restart terminal and voila.

Edington

Thank you for that. I've never known why etc/paths existed. It's much easier to use than all the export PATH stuff I've used in the past. – Hydrodynamic

This was the only way that worked for me on Monterey. Thanks. – Linotype

I've been pulling my hair for about 2 hours. I finally found the answer here. Thanks! This worked with Mac OS Monterey 12.5.1 – Penninite

Answer 8

I'm on Monterey 12.4 and the only way I could change the path was using the helper function. Editing text files in nano did diddly squat

# append
path+=('/foo/bar/yourpath')
# export to sub-processes 
export PATH

Sodamide

Answer 9

for me PATH=$PATH:/path/to/file/bin then export PATH worked. to check echo $PATH . other solutions are adding the path temporarily.

Saadi

Answer 10

You can add new file to /etc/paths.d and you can add your path that file. Don't forget to restart your terminal.

**#create new file to /etc/paths.d**
  touch /etc/paths.d/[filename]
**#open created file and add your path**
  vi /etc/paths.d/[filename]
**#save and close file and restart terminal**

Chlorine

Answer 11

A native zsh way is to identify your install directory and create a file from where you will load your PATH modifications:

touch $ZSH/custom/usrenv.zsh

And add the new PATH directories like this inside that usrenv.zsh:

export PATH=$PATH:/home/myself/.foo/bin:/usr/local/bar/bin

The custom directory files *.zsh are sourced by default by the .oh-my-zsh.sh init script, as this snippet taken from it shows:

if [[ -z "$ZSH_CUSTOM" ]]; then
    ZSH_CUSTOM="$ZSH/custom"
fi
...
for config_file ("$ZSH_CUSTOM"/*.zsh(N)); do
  source "$config_file"
done
unset config_file

Poet

Answer 12

to verify your new directory has been added correctly, you can use

print -l $path

thanks to the fact that its type is known to be an array

Luckin

This answers a completely different question. – Vorster

Answer 13

The lower case path variable didn't work for me. When I opened up my .zshrc there was already an EXPORT PATH= "$HOME/.local/bin:$PATH", where $PATH is the current path variable set on the machine. All I did was append to the string adding a colon in front of the path. e.g. export PATH="$HOME/.local/bin:$PATH:$HOME/go/bin"`

Anything after the : are the new paths to be appended.

Feuilleton