What is a pre-revprop-change hook in SVN, and how do I create it?

Question

I wanted to edit a log comment in the repository browser and received an error message that no pre-revprop-change hook exists for the repository. Besides having a scary name, what is a pre-revprop-change hook, and how do I create it?

Lenrow

now this link is the second one, just after a link to this question :) – Malvern

The link about leads to VERY outdated SVNBook 1.0. The current one is 1.7 and 1.8 (nightly): svnbook.red-bean.com/en/1.8 – Bumper

Answer 1

Basically it's a script that is launched before unversioned property is modified on the repository, so that you can manage more precisely what's happening on your repository.

There are templates in the SVN distrib for different hooks, located in the /hooks subdirectory (*.tmpl that you have to edit and rename depending on your OS, to activate).

Chaulmoogra

All the instructions are in the hook template script. If you need the hook for an svnsync mirror, then the default script will need to be changed, because it only allows changes to svn:log. Svnsync changes more than this, so I simply put an exit 0 in there to allow all property changes (since this is a mirror for me only). – Diarist

... then save it as pre-revprop-change to the same directory and make it executable for the web server user (on Linux). – Unmixed

Answer 2

For Windows, here's a link to an example batch file that only allows changes to the log message (not other properties):

http://ayria.livejournal.com/33438.html

Basically copy the code below into a text file and name it pre-revprop-change.bat and save it in the \hooks subdirectory for your repository.

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the log message to be changed, but not author, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:log messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

Kendalkendall

Could have linked to the version there #6655. I wrote that hook and posted it on SVN forum a while ago. I guess I should have put some credits in the hook comments. – Colossus

I'm using this script with VisualSVN 2.0.8 and TortoiseSVN 1.6.11 and it works nicely. – Confectionery

You can edit hooks in VisualSVN by right-clicking your repository name in VisualSVN Server and selecting "Properties...". You'll see a "Hooks" tab. In there you'll see the different types of hooks available. Select the right one, click "Edit" and paste the above code into it. Hope that helps VisualSVN users! – Elamitic

Worked for me disabling line: if /I not "%action%" == "M" goto ERROR_ACTION. Other way, it kept saying only modifications allowed. – Wireworm

Quick and dirty method for windows is to create an empty file called hooks\pre-revprop-change.bat – Sagittal

This continues to work in VisualSVN 3.5.6 & TortoiseSVN 1.9.4. – Concrescence

I have created an enhancement to that script, which saves the old and the new log message to a text file: stackoverflow.com/a/66366955 – Glyceric

Answer 3

For Linux to allow the edition of a log comment,

• locate the file pre-revprop-change.tmpl in the hooks directory of your repository
• copy the file to the same directory, renaming it to pre-revprop-change
• give execute permission to the file (for the server user, e.g. www-data)

Edited: (thanks to lindes)

• after that you might have to edit the script to return an exit value of 0 for the kind of edits, that you want to allow.

Rattoon

This is insufficient... one still needs to change the exit values appropriately. But I found it helpful anyway, as a pointer to the right place to look... which some of other answers were lacking, or giving windows-specific answers to. So thanks for this. – Inspectorate

I am pretty sure, in my Ubuntu Linux version copying and giving permission was enough . But I don't know for sure anymore. I have edited the answer accordingly. Thanks. – Rattoon

Well, I'm certain it didn't work for me as-is when I tried it 2 days ago, and added this comment. With the edit, though, this answer works for me. – Inspectorate

Answer 4

Here is the link to the stack overflow question with many common hooks Common Types of Subversion Hooks, including the original source of the pre-revprop-change hook for Windows cross-posted here.

You should refer there as they may get improved over time.

Colossus

Answer 5

Thanks #patmortech

And I added your code which "only the same user can change his code".

:: Only allow editing of the same user.
for /f "tokens=*" %%a in ( 
'"%VISUALSVN_SERVER%\bin\svnlook.exe" author -r %revision% %repository%') do ( 
set orgAuthor=%%a
)
if /I not "%userName%" == "%orgAuthor%" goto ERROR_SAME_USER

Doby

Answer 6

The name of the hook script is not so scary if you manage decipher it: it's pre revision property change hook. In short, the purpose of pre-revprop-change hook script is to control changes of unversioned (revision) properties and to send notifications (e.g. to send an email when revision property is changed).

There are 2 types of properties in Subversion:

• versioned properties (e.g svn:needs-lock and svn:mime-type) that can be set on files and directories,
• unversioned (revision) properties (e.g. svn:log and svn:date) that are set on repository revisions.

Versioned properties have history and can be manipulated by ordinary users who have Read / Write access to a repository. On the other hand, unversioned properties do not have any history and serve mostly maintenance purpose. For example, if you commit a revision it immediately gets svn:date with UTC time of your commit, svn:author with your username and svn:log with your commit log message (if you specified any).

As I already specified, the purpose of pre-revprop-change hook script is to control changes of revision properties. You don't want everyone who has access to a repository to be able to modify all revision properties, so changing revision properties is forbidden by default. To allow users to change properties, you have to create pre-revprop-change hook.

The simplest hook can contain just one line: exit 0. It will allow any authenticated user to change any revision property and it should not be used in real environment. On Windows, you can use batch script or PowerShell-based script to implement some logic within pre-revprop-change hook.

This PowerShell script allows to change svn:log property only and denies empty log messages.

# Store hook arguments into variables with mnemonic names
$repos    = $args[0]
$rev      = $args[1]
$user     = $args[2]
$propname = $args[3]
$action   = $args[4]

# Only allow changes to svn:log. The author, date and other revision
# properties cannot be changed
if ($propname -ne "svn:log")
{
  [Console]::Error.WriteLine("Only changes to 'svn:log' revision properties are allowed.")
  exit 1
}

# Only allow modifications to svn:log (no addition/overwrite or deletion)
if ($action -ne "M")
{
  [Console]::Error.WriteLine("Only modifications to 'svn:log' revision properties are allowed.")
  exit 2
}

# Read from the standard input while the first non-white-space characters
$datalines = ($input | where {$_.trim() -ne ""})
if ($datalines.length -lt 25)
{
  # Log message is empty. Show the error.
  [Console]::Error.WriteLine("Empty 'svn:log' properties are not allowed.")
  exit 3
}

exit 0

This batch script allows only "svnmgr" user to change revision properties:

IF "%3" == "svnmgr" (goto :label1) else (echo "Only the svnmgr user may change revision properties" >&2 )

exit 1
goto :eof

:label1
exit 0

Bumper

Answer 7

If you want to save the changes on the log messages, use the batch script from the answer above from @patmortech (https://stackoverflow.com/a/468475),
who copied the script from https://stackoverflow.com/a/68850,
and add these lines between if "%bIsEmpty%" == "true" goto ERROR_EMPTY and goto :eofbefore:

set outputFile=%repos%\log-change-history.txt

echo User '%user%' changes log message in rev %rev% on %date% %time%.>>%outputFile%
echo ----- Old message: ----->>%outputFile%
svnlook propget --revprop %repos% svn:log -r %rev% >>%outputFile%
echo.>>%outputFile%
echo ----- New message: ----->>%outputFile%
for /f "tokens=*" %%g in ('find /V ""') do (echo %%g >>%outputFile%)
echo ---------->>%outputFile%
echo.>>%outputFile%

It will create a text file log-change-history.txt in the repo folder on the server and append each log change notification.

Glyceric

Great solution. To be compatible to your suggested source the variable names have to be adapted. And the label where to copy it is named :eof. – Sateia

Answer 8

For PC users: The .bat extension did not work for me when used on Windows Server maching. I used VisualSvn as Django Reinhardt suggested, and it created a hook with a .cmd extension.

Costly

Answer 9

1. Go to SVN repo directory into the subfolder "hooks", e.g. "D:\SVN\hooks\"
2. create the empty file "pre-revprop-change.bat" there
3. in the file write "exit 0" (without "") and save it
4. enjoy :)

(This solution surely has drawbacks, as nothing is checked/prohibited. But for my case - a local repo that only I am using - it seems to work.)

Lactic

Answer 10

This was the easiest for me on a Windows Server: In VisualSVN right-click your repository, then select Properties... and then the Hooks tab.

Select Pre-revision property change hook, click Edit.

I needed to be able to change the Author - it often happens on remote computers used by multiple people, that by mistake we check-in using someone else's stored credentials.

Here is the modified community wiki script to paste:

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the author to be changed, but not message ("svn:log"), etc.
if /I not "%propertyName%" == "svn:author" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:author messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:author messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:author revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

Dialect

Answer 11

As Alois Helmer answered before, you need to locate the file pre-revprop-change.tmpl in the hooks directory inside the SVN repository you want to allow revision comments edition.

For me, to create a copy with pre-revprop-change name was sufficient, though you could edit it to allow only certain users to modify the comments or some other needs you have.

And then you must grant regular read and execution permissions using chmod 755 pre-revprop-change

But regular execution permissions are not enough. You need to give Apache/HTTPD execution grants in SELinux for that script like this.

chcon -t httpd_exec_t pre-revprop-change

If you not, you'll get the following error that gives little information and it's hard to relate to a SELinux conf.

svnrdump: E175008: Revprop change blocked by pre-revprop-change hook (exit code 255) with no output.

Entwistle