Relative Line Numbers In Emacs

B

6

29

Does anyone know how if something like this Vim Relative Line Numbers exists for emacs? I use vimpulse, and man, that would be super handy to have! I know some lisp, so if it doesn't, I could try to make my own, if I got a point in the right direction.

Update: Thanks to the correct response, I came up with this, that will show 1 for the current line, and -1 for the previous line, for combining with vimpulse yanks and deletes.

Thanks a ton to all who helped! I know it is not exactly what Vim does, but what good is the Relative line numbers in vim that start at zero?? Silly vim.

(defvar my-linum-current-line-number 0)

(setq linum-format 'my-linum-relative-line-numbers)

(defun my-linum-relative-line-numbers (line-number)
  (let ((test2 (1+ (- line-number my-linum-current-line-number))))
    (propertize
     (number-to-string (cond ((<= test2 0) (1- test2))
                             ((> test2 0) test2)))
     'face 'linum)))

(defadvice linum-update (around my-linum-update)
  (let ((my-linum-current-line-number (line-number-at-pos)))
    ad-do-it))
(ad-activate 'linum-update)

Barabarabarabas answered 29/7, 2011 at 14:16 Comment(4)

Like Steve said, he uses vimpulse in Emacs. emacswiki.org/emacs/Vimpulse – Vince 29/7, 2011 at 16:52

@Vince - ah, thanks, missed that bit of the post. – Seko 29/7, 2011 at 17:50

Steve, I've taken the liberty of updating your version with a bug fix to use the correct face for the linum-format function output. – Vince 13/3, 2012 at 13:9

BTW: Regarding such a "relative line number" feature, how should it behave when the buffer is displayed in several windows: should the "other windows" show line numbers relative to their respective points, or to the point in the currently selected window (and if so, what should happen if none of the buffer's windows is the selected window)? – Balliett 29/9, 2015 at 13:45

V

14

(2012-03-16: line numbers are now right-aligned, and displayed in the correct face.)

The problem here is that by the time a custom linum-format function is called, point has already been moved (by linum-update-window) to the line in question, so we can no longer use it to establish the difference between the two lines; it would just print a zero for every line.

There is a linum-before-numbering-hook, but this is run after point has been moved to the start of the buffer, so that's not useful for our purpose.

The following code solves the problem by using advice for linum-update to store the current line number, so that it will be available to the custom linum-format function.

To right-align the numbers I initially used a hard-coded format string of %3d on the basis that a single window showing more than 100 lines of code was not terribly likely. If you're a fan of follow-mode, however (or simply have multiple windows on the same buffer), that circumstance becomes exceedingly likely; so the code now calculates the number of columns required dynamically. The use of linum-before-numbering-hook makes this more efficient than the approach taken by the default dynamic linum format.

Note that if you comment out the add-hook, the faster non-dynamic approach is used.

(defvar my-linum-format-string "%3d")

(add-hook 'linum-before-numbering-hook 'my-linum-get-format-string)

(defun my-linum-get-format-string ()
  (let* ((width (1+ (length (number-to-string
                             (count-lines (point-min) (point-max))))))
         (format (concat "%" (number-to-string width) "d")))
    (setq my-linum-format-string format)))

(defvar my-linum-current-line-number 0)

(setq linum-format 'my-linum-relative-line-numbers)

(defun my-linum-relative-line-numbers (line-number)
  (let ((offset (- line-number my-linum-current-line-number)))
    (propertize (format my-linum-format-string offset) 'face 'linum)))

(defadvice linum-update (around my-linum-update)
  (let ((my-linum-current-line-number (line-number-at-pos)))
    ad-do-it))
(ad-activate 'linum-update)

Vince answered 3/8, 2011 at 14:28 Comment(10)

Two questions. How can I have the negative line numbers without the - prefix? And how can I avoid the line numbers getting the same face settings at the line they represent? For example, line numbers for commented out lines get the same color applied as the comments themselves. – Backwoods 13/3, 2012 at 12:6

To remove the minus sign, just call abs to get the absolute value of the number. i.e.: (number-to-string (abs (- line-number my-linum-current-line-number))) – Vince 13/3, 2012 at 12:32

For question two, my code was missing a trick: when linum-format is a function, the return value is not automatically propertized with the linum face. I've updated the code above to take care of that. You can then M-x customize-group RET linum RET if you wish to modify the face further. – Vince 13/3, 2012 at 13:1

Thanks, works great :)... I just have one last question, how do you right-align or left-pad the line numbers? For example, the line-numbers look left-aligned here: cl.ly/2J1i1T2B0Q0N13181g24 – Backwoods 14/3, 2012 at 15:15

Thanks again :D... I did add a abs call though, as I find it just looks weird having negative numbers. And looks to me like follow-mode would only be an issue if you can get 1000 or more lines on the screen at once. But then that might be due to me removing the - character... lol – Backwoods 20/3, 2012 at 0:15

I've taken this code and written relative-linum.el on EmacsWiki so others can use it. Check it out: emacswiki.org/emacs/relative-linum.el . I hope that's OK :) – Colombia 11/7, 2012 at 13:30

Sure (if you add " by phils" after the stackoverflow URL, that would be fine for attribution), except I can only suggest removing the things you've added to it: your relative-linum-jump is basically identical to the forward-line function it calls, and so doesn't really serve a purpose; and you're clobbering a binding that you shouldn't be using. – Vince 11/7, 2012 at 14:27

The solution works, unfortunately it also causes a lot of annoying "flashing" (slow redraws, I guess) when moving the cursor at least of Emacs24 + Windows. Ultimately this is something that should probably be implemented in the core. – Hutchison 12/9, 2014 at 7:51

juanjux: Try running emacs -Q and see if you still have that issue after loading this code. At the time I wrote it, this was actually more efficient than the default linum (but I think that's been sorted out in the interim). In any case, I'd be surprised if you were having issues with this code that you weren't having with un-modified linum? Try byte-compiling the code, if you hadn't already done so. You might also investigate the nlinum package, which was written by an Emacs maintainer to be a more efficient replacement for linum. – Vince 12/9, 2014 at 8:7

I do not know whether it will work for your answer, but I have obtained great speed increases in a custom minor mode by using: (save-excursion (goto-char (point-max)) (format-mode-line "%l")) instead of count-lines, which causes slow-downs in large buffers. emacs.stackexchange.com/a/3822/2287 You have a few occurrences in the answer as it stands now -- i.e., line-number-at-pos relies upon count-lines and you have count-lines separately as well. – Seethe 28/9, 2015 at 23:8

T

42

In Emacs 26.1, there's a built-in line number mode (display-line-numbers-mode). Enable it and set (setq display-line-numbers 'relative) to use relative line numbers.

Terracotta answered 27/1, 2019 at 21:4 Comment(3)

For me (setq display-line-numbers-type 'relative) enabled it globally. (Emacs 26.3) – Timbering 11/1, 2021 at 14:49

@Timbering display-line-numbers-type works perfectly – Architect 11/5, 2021 at 4:35

Should also add (global-display-line-numbers-mode) to enable number for all buffer automatically. – Arsenical 11/9, 2021 at 15:26

V

14

(2012-03-16: line numbers are now right-aligned, and displayed in the correct face.)

The problem here is that by the time a custom linum-format function is called, point has already been moved (by linum-update-window) to the line in question, so we can no longer use it to establish the difference between the two lines; it would just print a zero for every line.

There is a linum-before-numbering-hook, but this is run after point has been moved to the start of the buffer, so that's not useful for our purpose.

The following code solves the problem by using advice for linum-update to store the current line number, so that it will be available to the custom linum-format function.

To right-align the numbers I initially used a hard-coded format string of %3d on the basis that a single window showing more than 100 lines of code was not terribly likely. If you're a fan of follow-mode, however (or simply have multiple windows on the same buffer), that circumstance becomes exceedingly likely; so the code now calculates the number of columns required dynamically. The use of linum-before-numbering-hook makes this more efficient than the approach taken by the default dynamic linum format.

Note that if you comment out the add-hook, the faster non-dynamic approach is used.

(defvar my-linum-format-string "%3d")

(add-hook 'linum-before-numbering-hook 'my-linum-get-format-string)

(defun my-linum-get-format-string ()
  (let* ((width (1+ (length (number-to-string
                             (count-lines (point-min) (point-max))))))
         (format (concat "%" (number-to-string width) "d")))
    (setq my-linum-format-string format)))

(defvar my-linum-current-line-number 0)

(setq linum-format 'my-linum-relative-line-numbers)

(defun my-linum-relative-line-numbers (line-number)
  (let ((offset (- line-number my-linum-current-line-number)))
    (propertize (format my-linum-format-string offset) 'face 'linum)))

(defadvice linum-update (around my-linum-update)
  (let ((my-linum-current-line-number (line-number-at-pos)))
    ad-do-it))
(ad-activate 'linum-update)