In my batch file on Windows XP, I want to use %* to expand to all parameters except the first.
Test file (foo.bat):
@echo off
echo %*
shift
echo %*
Call:
C:\> foo a b c d e f
Actual result:
a b c d e f
a b c d e f
Desired result:
a b c d e f
b c d e f
How can I achieve the desired result? Thanks!!
Wouldn't it be wonderful if CMD.EXE worked that way! Unfortunately there is not a good syntax that will do what you want. The best you can do is parse the command line yourself and build a new argument list.
Something like this can work.
@echo off
setlocal
echo %*
shift
set "args="
:parse
if "%~1" neq "" (
set args=%args% %1
shift
goto :parse
)
if defined args set args=%args:~1%
echo(%args%
But the above has problems if an argument contains special characters like ^, &, >, <, | that were escaped instead of quoted.
Argument handling is one of many weak aspects of Windows batch programming. For just about every solution, there exists an exception that causes problems.
set arg1=%1 & set argsRemainder=%2 %3 %4 %5 %6 %7 %8 %9. At which point the most command use case is straight forward, e.g. echo executing some command that needs arg1 = %arg1% and argRemainder = %argsRemainder% references ? –
Reprieve %0). SHIFT is used to access arguments beyond %9. –
Carlinecarling That´s easy:
setlocal ENABLEDELAYEDEXPANSION
set "_args=%*"
set "_args=!_args:*%1 =!"
echo/%_args%
endlocal
Same thing with comments:
:: Enable use of ! operator for variables (! works as % after % has been processed)
setlocal ENABLEDELAYEDEXPANSION
set "_args=%*"
:: Remove %1 from %*
set "_args=!_args:*%1 =!"
:: The %_args% must be used here, before 'endlocal', as it is a local variable
echo/%_args%
endlocal
Example:
lets say %* is "1 2 3 4":
setlocal ENABLEDELAYEDEXPANSION
set "_args=%*" --> _args=1 2 3 4
set "_args=!_args:*%1 =!" --> _args=2 3 4
echo/%_args%
endlocal
Remarks:
! or & char%_args% must be used before endlocal, because it is a local variable%_args% returns * =* to remove everything through the first instance: set _args=!_args:*%1=!. Other problems that cannot be fixed is it will fail if %1 contains ! or =. –
Carlinecarling Don't think there's a simple way to do so. You could try playing with the following workaround instead:
@ECHO OFF
>tmp ECHO(%*
SET /P t=<tmp
SETLOCAL EnableDelayedExpansion
IF DEFINED t SET "t=!t:%1 =!"
ECHO(!t!
Example:
test.bat 1 2 3=4
Output:
2 3=4
set t=%* would work just as well. This answer will fail if %1 contains = or starts with * or ~. Also will have problems if args are delimited with , or ; instead of spaces. Better to only remove %1 and leave the delimiter(s) in place. –
Carlinecarling A A B. Could be improved with set t=!t:*%1=! –
Carlinecarling set "t=!t:*%1=! modification, this answer will still fail if %1 contains =, but starting with * or ~ is ok. –
Carlinecarling set /p I was just being overcautious about something, not sure now about what exactly, and so you may well be right about set t=%* being no worse than using a temp file. And I agree with you on your other points. Basically, it turns out that despite batch scripting being already weak in argument handling, I managed to add even more restraint with my suggestion. :) There's a couple of (minor) advantages of my script over yours, though: =s and , are preserved if they are not part of the first argument: 1 2,3 -> 2,3 and 1 2=3 -> 2=3. –
Abettor 2=3 is kind of pointless if it is passed on to another batch script since batch will parse it as 2 arguments 2 and 3. The batch token delimiters are ,, ;, =, <space>, <tab>. If you pass on 2=3 to something other than batch, then yes it could be important. –
Carlinecarling I had to do this recently and came up with this:
setlocal EnableDelayedExpansion
rem Number of arguments to skip
set skip=1
for %%a in (%*) do (
if not !position! lss !skip! (
echo Argument: '%%a'
) else (
set /a "position=!position!+1"
)
)
endlocal
It uses loop to skip over N first arguments. Can be used to execute some command per argument or build new argument list:
setlocal EnableDelayedExpansion
rem Number of arguments to skip
set skip=1
for %%a in (%*) do (
if not !position! lss !skip! (
set args=!args! %%a
) else (
set /a "position=!position!+1"
)
)
echo %args%
endlocal
Please note that the code above will add leading space to the new arguments. It can be removed like this:
UPDATE: The implementation is replaced by more reliable one. Use the link below to directly download the scripts.
Pros:
%* variable including
additional command line arguments.Cons:
& and | still must be escaped before
call in a user script (side issue).setlocal DISABLEDELAYEDEXPANSION, otherwise the ! character will be
expanded.You can shift arguments before call to another command.
CAUTION:
Seems the stackoverflow incorrectly handles tabulation characters (and loses other characters like \x01 or \x04) in the copy-pasted code, so the below code might not work if you copy it directly by CTRL+C. Use the link below to directly download the scripts.
Implementation: https://github.com/andry81/contools/tree/HEAD/Scripts/Tools/std/callshift.bat
@echo off
rem USAGE:
rem callshift.bat [-no_trim] [-skip <skip-num>] <shift> <command> [<cmdline>...]
rem Description:
rem Script calls second argument and passes to it all arguments beginning
rem from %3 plus index from %1. Script can skip first N arguments after %2
rem before shift the rest.
rem -no_trim
rem Avoids spaces trim in the shifted command line.
rem -skip <skip-num>
rem Additional number of skip arguments after %2 argument.
rem If not defined, then 0.
rem <shift>:
rem Number of arguments in <cmdline> to skip and shift.
rem If >=0, then only shifts <cmdline> after %2 argument plus <skip-num>.
rem If < 0, then skips first <shift> arguments after %2 argument plus
rem <skip-num> and shifts the rest <cmdline>.
rem <command>:
rem Command to call with skipped and shifted arguments from <cmdline>.
rem Examples:
rem 1. >callshift.bat 0 echo "1 2" ! ^^? ^^* ^& ^| , ; = ^= "=" 3
rem "1 2" ! ? * & | , ; "=" 3
rem 2. >callshift.bat 2 echo."1 2" 3 4 5
rem "1 2" 5
rem 3. >callshift.bat . set | sort
rem 4. >errlvl.bat 123
rem >callshift.bat
rem >callshift.bat 0 echo.
rem >callshift.bat 0 echo 1 2 3
rem >echo ERRORLEVEL=%ERRORLEVEL%
rem ERRORLEVEL=123
rem 5. >callshift.bat -3 echo 1 2 3 4 5 6 7
rem 1 2 3 7
rem rem in a script
rem >call callshift.bat -3 command %%3 %%2 %%1 %%*
rem 6. >callshift.bat -skip 2 -3 echo a b 1 2 3 4 5 6 7
rem a b 1 2 3 7
rem rem in a script
rem >call callshift.bat -skip 2 -3 command param0 param1 %%3 %%2 %%1 %%*
rem 7. >callshift.bat 0 exit /b 123
rem >echo ERRORLEVEL=%ERRORLEVEL%
rem ERRORLEVEL=123
rem 8. >errlvl.bat 123
rem >callshift.bat 0 call errlvl.bat 321
rem >echo ERRORLEVEL=%ERRORLEVEL%
rem ERRORLEVEL=321
rem 9. >callshift.bat -no_trim 1 echo a b c d
rem b c d
rem Pros:
rem
rem * Can handle `!`, `?`, `*`, `&`, `|`, `,`, `;`, `=` characters.
rem * Can call builtin commands.
rem * Does restore previous ERRORLEVEL variable before call a command.
rem * Does not leak variables outside.
rem * Can skip first N used arguments from the `%*` variable including
rem additional command line arguments.
rem * Can avoid spaces trim in the shifted command line.
rem
rem Cons:
rem
rem * The control characters like `&` and `|` still must be escaped.
rem * To handle `?` and `*` characters you must prefix them additionally to escape: `^?`, `^*`.
rem * Can not handle `=` character without quotes.
rem * Does write to a temporary file to save the command line as is.
rem with save of previous error level
setlocal & set LAST_ERROR=%ERRORLEVEL%
rem drop last error level
call;
set "CMDLINE_TEMP_FILE=%TEMP%\callshift.%RANDOM%-%RANDOM%.txt"
rem redirect command line into temporary file to print it correcly
for %%i in (1) do (
set "PROMPT=$_"
echo on
for %%b in (1) do rem %*
@echo off
) > "%CMDLINE_TEMP_FILE%"
for /F "usebackq eol= tokens=* delims=" %%i in ("%CMDLINE_TEMP_FILE%") do set "LINE=%%i"
del /F /Q "%CMDLINE_TEMP_FILE%" >nul 2>nul
rem script flags
set FLAG_SHIFT=0
set FLAG_SKIP=0
set FLAG_NO_TRIM=0
rem flags always at first
set "FLAG=%~1"
if defined FLAG ^
if not "%FLAG:~0,1%" == "-" set "FLAG="
if defined FLAG (
if "%FLAG%" == "-no_trim" (
set FLAG_NO_TRIM=1
shift
set /A FLAG_SHIFT+=1
)
)
if defined FLAG (
if "%FLAG%" == "-skip" (
set "FLAG_SKIP=%~2"
shift
shift
set /A FLAG_SHIFT+=2
)
)
set "SHIFT=%~1"
set "COMMAND="
set "CMDLINE="
rem cast to integer
set /A FLAG_SKIP+=0
set /A SHIFT+=0
set /A COMMAND_INDEX=FLAG_SHIFT+1
set /A ARG0_INDEX=FLAG_SHIFT+2
set /A SKIP=FLAG_SHIFT+2+FLAG_SKIP
if %SHIFT% GEQ 0 (
set /A SHIFT+=FLAG_SHIFT+2+FLAG_SKIP
) else (
set /A SKIP+=-SHIFT
set /A SHIFT=FLAG_SHIFT+2+FLAG_SKIP-SHIFT*2
)
rem Escape specific separator characters by sequence of `$NN` characters:
rem 1. `?` and `*` - globbing characters in the `for %%i in (...)` expression
rem 2. `,`, `;`, <space> - separator characters in the `for %%i in (...)` expression
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE:$=$00!") do endlocal & set "LINE=%%i"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE:^*=$01!") do endlocal & set "LINE=%%i"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE:^?=$02!") do endlocal & set "LINE=%%i"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE:,=$03!") do endlocal & set "LINE=%%i"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE:;=$04!") do endlocal & set "LINE=%%i"
if %FLAG_NO_TRIM% NEQ 0 (
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE: = $05!") do endlocal & set "LINE=%%i"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%i in ("!LINE:$05 =$05$05!") do endlocal & set "LINE=%%i"
)
set INDEX=-1
setlocal ENABLEDELAYEDEXPANSION
for /F "eol= tokens=* delims=" %%i in ("!LINE!") do endlocal & for %%j in (%%i) do (
setlocal ENABLEDELAYEDEXPANSION
if !INDEX! GEQ !ARG0_INDEX! (
if !INDEX! LSS !SKIP! (
if defined CMDLINE (
for /F "eol= tokens=* delims=" %%v in ("!CMDLINE!") do endlocal & set "CMDLINE=%%v %%j"
) else endlocal & set "CMDLINE=%%j"
) else if !INDEX! GEQ !SHIFT! (
if defined CMDLINE (
for /F "eol= tokens=* delims=" %%v in ("!CMDLINE!") do endlocal & set "CMDLINE=%%v %%j"
) else endlocal & set "CMDLINE=%%j"
) else endlocal
) else if !INDEX! EQU !COMMAND_INDEX! (
endlocal & set "COMMAND=%%j"
) else endlocal
set /A INDEX+=1
)
if defined COMMAND (
setlocal ENABLEDELAYEDEXPANSION
for /F "eol= tokens=* delims=" %%i in ("!COMMAND!") do (
if defined CMDLINE (
for /F "eol= tokens=* delims=" %%v in ("!CMDLINE:$04=;!") do endlocal & set "CMDLINE=%%v"
if %FLAG_NO_TRIM% NEQ 0 setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%v in ("!CMDLINE:$05= !") do endlocal & set "CMDLINE=%%v"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%v in ("!CMDLINE:$03=,!") do endlocal & set "CMDLINE=%%v"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%v in ("!CMDLINE:$02=?!") do endlocal & set "CMDLINE=%%v"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%v in ("!CMDLINE:$01=*!") do endlocal & set "CMDLINE=%%v"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%v in ("!CMDLINE:$00=$!") do endlocal & set "CMDLINE=%%v"
setlocal ENABLEDELAYEDEXPANSION & for /F "eol= tokens=* delims=" %%v in ("!CMDLINE!") do endlocal & endlocal & call :SETERRORLEVEL %LAST_ERROR% & %%i %%v
) else endlocal & endlocal & call :SETERRORLEVEL %LAST_ERROR% & %%i
exit /b
)
exit /b %LAST_ERROR%
)
(
endlocal
exit /b %LAST_ERROR%
)
:SETERRORLEVEL
exit /b %*
Examples:
>callshift.bat 0 echo "1 2" ! ^^? ^^* ^& ^| , ; = ^= "=" 3
"1 2" ! ? * & | , ; "=" 3
>callshift.bat 2 echo."1 2" 3 4 5
"1 2" 5
>callshift.bat . set | sort
>errlvl.bat 123
>callshift.bat
>callshift.bat 0 echo.
>callshift.bat 0 echo 1 2 3
>echo ERRORLEVEL=%ERRORLEVEL%
ERRORLEVEL=123
>callshift.bat -3 echo 1 2 3 4 5 6 7
1 2 3 7
rem in a script
>call callshift.bat -3 command %%3 %%2 %%1 %%*
>callshift.bat -skip 2 -3 echo a b 1 2 3 4 5 6 7
a b 1 2 3 7
rem in a script
>call callshift.bat -skip 2 -3 command param0 param1 %%3 %%2 %%1 %%*
>callshift.bat -no_trim 1 echo a b c d
b c d
Pros:
!, ?, *, &, |, ,, ;, = characters.%* variable including additional command line arguments.Cons:
& and | still must be escaped.? and * characters you must prefix them additionally to escape: ^?, ^*.= character without quotes.Another easy way of doing this is:
set "_args=%*"
set "_args=%_args:* =%"
echo/%_args%
Remarks:
Yet another obnoxious shortcoming of DOS/Windows batch programming...
Not sure if this is actually better than some of the other answers here but thought I'd share something that seems to be working for me. This solution uses FOR loops rather than goto, and is contained in a reusable batch script.
Separate batch script, "shiftn.bat":
@echo off
setlocal EnableDelayedExpansion
set SHIFTN=%1
FOR %%i IN (%*) DO IF !SHIFTN! GEQ 0 ( set /a SHIFTN=!SHIFTN! - 1 ) ELSE ( set SHIFTEDARGS=!SHIFTEDARGS! %%i )
IF "%SHIFTEDARGS%" NEQ "" echo %SHIFTEDARGS:~1%
How to use shiftn.bat in another batch script; in this example getting all arguments following the first (skipped) arg:
FOR /f "usebackq delims=" %%i IN (`call shiftn.bat 1 %*`) DO set SHIFTEDARGS=%%i
Perhaps someone else can make use of some aspects of this solution (or offer suggestions for improvement).
Resume of all and fix all problems:
set Args=%1
:Parse
shift
set First=%1
if not defined First goto :EndParse
set Args=%Args% %First%
goto :Parse
:EndParse
Unsupport spaces between arguments: 1 2 3 4 will be 1 2 3 4
© 2022 - 2024 — McMap. All rights reserved.
\t\r\n^Back Slashandquote. github.com/zhanhb/kcptun-sip003-wrapper/blob/v0.1/src/… – Spanjian