Better Way to Define an Enum in Haskell

Question

I want a datatype to represent a finite set of integers that can be addressed by specific names. I figure the best way to do that is to use an Enum.

However, there is one small problem. The only way I know for defining an Enum is something like this:

data MyDataType = Foo | Bar | Baz

instance Enum MyDataType 
 toEnum 0 = Foo
 toEnum 1 = Bar
 toEnum 2 = Baz

 fromEnum Foo = 0
 fromEnum Bar = 1
 fromEnum Baz = 2 

Note that I have to repeat the same pair two times - one time when defining an integer-to-enum mapping and the other time when defining an enum-to-integer mapping.

Is there a way to avoid this repetition?

Cosmography

Do you know about deriving Enum ? It is magical! – Northeastwards

Ok, but it probably will not work if the values that are assigned to the names are not sequential, e.g. Foo should be 2, Bar should be 4, Baz should be 8, etc. – Cosmography

Aside from Augustss's suggestion, a method I've used is to derive Enum and place filler types in the gaps (when the gaps are small): data SomeEnum = ValueA | Reserved1 | Reserved2 | ValueB | Reserved3 | ValueC – Xuthus

Something to note, though - long hand, as per the code in the question, is both efficient and clear. Sometimes scraping boilerplate isn't the best path. – Avant

If the values you want are in fact 2, 4, 8, 16, etc. it seems to me there might be another way. Like, use deriving Enum, but then write your own version of the toEnum' and fromEnum' which call toEnum and fromEnum and then do the 2^x conversion. Whether this is any better, I don't know. – Hawaii

If the values are not continuous, then I would not define an Enum instance, at all. If you need powers of two, maybe you want to use the enumset package for defining flag sets? – Bettyebettzel

Answer 1

instance Enum MyDataType where
    fromEnum = fromJust . flip lookup table
    toEnum = fromJust . flip lookup (map swap table)
table = [(Foo, 0), (Bar, 1), (Baz, 2)]

Secund

...where swap is the obvious swap (x,y) = (y,x) (defined in Data.Tuple in the latest Haskell Platform) – Finback

I know I am not supposed to care, but will this be optimized into something efficient by ghc? – Mccracken

@Florian, probably not. It's possible to write similar things that probably will be. – Ori

will GHC at least realise to only generate the swapped table (map swap table) once? – Quass

Something to be aware of when you're using this to assign your own integer values in a custom Enum instance is that the default definitions of all the other methods of Enum in terms of fromEnum and toEnum make the assumption that they can use arithmetic on the integer codes to step between values. For example the default definition of succ is just succ = toEnum . (+ 1) . fromEnum, which doesn't work if you're not using a continuous subset of Int as your codes. You need to define the other methods too – Anaemic

Answer 2

data MyDataType = Foo | Bar | Baz deriving (Enum)

Finback

Good for sequential enum values (like in my example), but will it work if the values are not sequential (e.g. Foo should be 2, Bar should be 4, and so on?) – Cosmography

Not directly - but if you can write a bijective function f which turns the consecutive integers from 0..n into the integers you want, you can define a newtype MyRealDataType = MyRealDataType MyDataType and give it an Enum instance which "corrects" the values produced by the Enum instance of MyDataType. The disadvantage is you have to unwrap it when you want to pattern match directly on the names, etc. – Finback

Problem is, there is no specific law according to which the values change (they are not powers of 2, for example). – Cosmography

Answer 3

The problem with the accepted solution is the compiler won't tell you when you are missing an enum in your table. The deriving Enum solution is great, but it won't work if you want to have an arbitrary mapping to numbers. Another answer suggests Generics or Template Haskell. This follows up on that by using Data.

{-# Language DeriveDataTypeable #-}
import Data.Data
data MyDataType = Foo | Bar | Baz deriving (Eq, Show, Data, Typeable)

toNumber enum = case enum of
   Foo -> 1
   Bar -> 2
   Baz -> 4

We will get compiler warning in the toNumber case mapping when a new constructor is added.

Now we just need the ability to turn that code into data so that the mapping can be automatically reversed. Here we generate the same table mentioned in the accepted solution.

table = map (\cData -> let c = (fromConstr cData :: MyDataType) in (c, toNumber c) )
      $ dataTypeConstrs $ dataTypeOf Foo

You can fill out an Enum class just the same as in the accepted answer. Unmentioned there is that you can also fill out the Bounded class.

Parmenter

Answer 4

My examples here are using GHCI 8.4.4 with a prompt, "λ: ".

I think deriving from Enum makes the most sense here, as the most fundamental types in Haskell also derive from Enum (tuples, characters, integers, etc...), and it has builtin methods of getting values into and from the enum.

First, create a data type deriving Enum (and Show so you can view the value in the REPL and Eq to enable .. range completion):

λ: data MyDataType = Foo | Bar | Baz deriving (Enum, Show, Eq)
λ: [Foo ..]
[Foo,Bar,Baz]

Enums define a method, fromEnum, which you can use to get the values as requested in the question (0, 1, and 2).

Usage:

λ: map fromEnum [Foo ..]
[0,1,2]

It is a simple matter to define a function giving an arbitrary value (such as powers of two using the integer power operator, ^):

λ: value e = 2 ^ (fromEnum e)

Usage:

λ: map value [Foo ..]
[1,2,4]

Another answer says:

The deriving Enum solution is great, but it won't work if you want to have an arbitrary mapping to numbers.

Well, let's see about that (use :set +m to enable multiline input in GHCI, if you haven't already):

arbitrary e = case e of
  Foo -> 10
  Bar -> 200
  Baz -> 3000

Usage:

λ: map arbitrary [Foo ..]
[10,200,3000]

We just demonstrated that it does indeed work, but I would prefer to calculate it from the fromEnum as we did with value, if we do not want values increasing by 1 from 0.

Eckel

Answer 5

Since you say the numbers are not generated by any regular law, you could use generic programming (e.g. with Scrap Your Boilerplate) or Template Haskell to implement a generic solution to this problem. I tend to prefer Template Haskell because it actually generates code and compiles it, so you get all the type-checking and optimisation benefits of GHC.

I wouldn't be surprised if someone had implemented this already. It should be trivial.

Finback

OK, I should have thought of augustss's solution. The only advantage of this one is that you don't need to list out all the constructor names twice. – Finback

And yours gets optimized.and checked properly. – Ori