Gradle subproject name different than folder name

Question

I have a couple of subprojects that are part of a multi-project build (flat hierarchy). I want to set the name on them to be different than their folder name. However, in include (settings.gradle) it has to have the folder name otherwise it won't find it (same for the compile project(':ProjectName')).

If I attempt to set project.name it tells me that is read-only. The reason is that we are converting from Ant and would like to keep the same name for Eclipse IDE. As far the artifacts go, we use jar.artifactName to set whatever name we want.

Thank you.

Ericaericaceous

Answer 1

Project names can only be changed in settings.gradle. For example:

include "foo" // or `includeFlat`, doesn't matter

// always good to nail down the root project name, because
// the root directory name may be different in some envs (e.g. CI)
// hence the following even makes sense for single-project builds
rootProject.name = "bar" 

// change subproject name
project(":foo").name = "foofoo"

Alternatively, you can use the desired project name in the include statement, and later reconfigure the project directory:

include "foofoo"

project(":foofoo").projectDir = file("foo")

To give some background, the only difference between include and includeFlat is that they use different defaults for the project's projectDir. Otherwise they are the same.

For further information, check out Settings in the Gradle Build Language Reference.

Corpsman

That works fine. Thank you very much. I have to say I am liking gradle more and more every day as I learn more about it. – Ericaericaceous

What version of Gradle does this work for? I'm using 1.12 and get "Project with path ':foo' could not be found in root project 'bar'." project(':foo') definitely exists when inside build.gradle and I also have include "foo" before project(":foo"). – Demetri

It should work with pretty much any version. Where exactly do you get this error? What do you mean by "project(':foo') definitely exists when inside build.gradle"? – Corpsman

I'm running into the same issue as Travis on 1.12 – Hertfordshire

Once you changed the project name to foofoo, it's project(":foofoo"). – Corpsman

I wish there was a way for it to continue to use the old :projectOld:project2Old but create a different module name for IntelliJ. this would work around the issue when you have multiple sub-projects with the same name minus a few characters – Amphimixis

Does this still work? I'm using Gradle v7.6 and even after changing .name, I can access the subproject only by its original name. With the .projectDir method, I can't access the subproject at all. – Le

Answer 2

This is Kotlin DSL equivalent of Peter Niederwieser's answer.

settings.gradle.kts:

rootProject.name = "MyApp"

include(":Narengi")
project(":Narengi").name = "Bunny"

// OR

include(":Bunny")
project(":Bunny").projectDir = file("Narengi/")

Mallina