MessageDlg shows information icon instead of confirmation

Question

On Win 7, MessageDlg shows information icon instead of confirmation icon (question mark). Here is the code:

MessageDlg('Are you sure you want to delete this file?'+ CRLF+ FileName, mtConfirmation, [mbYes, mbNo], 0)= mrYes

What am I doing wrong?

Willams

See qc.embarcadero.com/wc/qcmain.aspx?d=91648 – Changteh

Answer 1

First, notice that a simple workaround is to use the Windows API MessageBox function instead:

MessageBox(Handle, 'This is a test.', 'Test', MB_ICONQUESTION or MB_YESNO)

But why doesn't MessageDlg work? Well, MessageDlg does one of two possible things. It uses the Windows Vista+ Task Dialog, if possible, that is, it the OS is Windows Vista or later and themes are enabled and the UseLatestCommonDialogs global variable is true (the default). If not, the VCL actually creates a custom TForm and adds all buttons, labels, and icons manually (which is a bit odd if you ask me -- why not simply use MessageBox?).

The last approach supports the question-mark icon. Indeed, try

UseLatestCommonDialogs := false;
MessageDlg('This is a test', mtConfirmation, [mbYes, mbNo], 0);

But this looks so ugly! Please don't do this! It is stupid to create a custom message dialog instead of using the native OS dialogs!

Unfortunately, however, the Task Dialog does not support the question-mark icon (as a pre-defined icon). This is not a restriction of the TTaskDialog wrapper, but a limitation of the Windows Task Dialog API. See the official documentation, for instance. There are TD_ERROR_ICON, TD_WARNING_ICON, and TD_INFORMATION_ICON, but no question-mark icon.

Of course, the Task Dialog can use any icon. For instance, you can do

if (Win32MajorVersion >= 6) and ThemeServices.ThemesEnabled then
    with TTaskDialog.Create(Self) do
      try
        Caption := 'Test';
        Title := 'Test';
        Text := 'This is a test.';
        CommonButtons := [tcbYes, tcbNo];
        CustomMainIcon.ReleaseHandle;
        CustomMainIcon.Handle := LoadIcon(0, IDI_QUESTION);
        Flags := [tfUseHiconMain];
        Execute;
      finally
        Free;
      end
  else
    MessageBox(Handle,
               'This is a test.',
               'Test',
               MB_ICONQUESTION or MB_YESNO);

Notice that I fall back on the old MessageBox should the Task Dialog API not be available.

In principle, the MessageDlg function could use additional logic to handle the question-mark case separately, in a way that differs from the information, warning, and error cases. This would have made the mtConfirmation give the right icon even with the Task Dialog, at the expence of slightly more complicated, and less elegant, VCL code. Apparently, however, Embarcadero chose the simpler alternative of simply pretending that you asked for the information icon.

Still, I wonder why Microsoft chose not to include a TD_QUESTION_ICON constant in the API. Perhaps this icon is discouraged in their latest UI guidelines?

Belvabelvedere

The ThemeServices.ThemesEnabled test made me chuckle. You do realise I trust that you have to do this due to a silly bug in the Delphi TTaskDialog. Task Dialog is available for Win32MajorVersion >= 6 and it works perfectly on Windows Classic. I've no idea why Embarcadero did it the way they did. As you might imagine, I use my own wrapper of the task dialog API due to such weaknesses. – Myo

@David: Yes, I have never understood why themes have to be enabled (but I haven't spent any time researching the issue, either). But sure, TTaskDialog has a few problems. Most importantly, it virtually lacks documentation. But it also has a few bugs, for instance this one. – Belvabelvedere

Hi Andreas. Actually I immediately switched to MessageBox when I have seen that MessageDlg is not working. I just wanted to what I was doing wrong. Thanks for your most complete explanation. Accepted. – Willams

Use Flags := Flags + [tfUseHiconMain]; otherwise you loose the close button of the dialog on Windows10 :) . +1 for the answer – Kelliekellina

When you have to display longer strings, MessageBox is much better than TTaskDialog because TTaskDialog will wrap your strings too soon (its width tends to be much smaller than MessageBox 's width). – Willams

It is not stupid to use a custom dialog, I want to localize my program but using the WinAPI I cannot change the button texts. Changing the Windows language does not work either, the language pack might not be installed. So my own message box is the only option. – Exasperation

Answer 2

If you need some Dialogs, you may take a look at our Open Source SynTaskDialog unit for Windows XP, Vista, Seven.

It will call the Native Task Dialog under Vista and Seven, and emulate it under XP. You'll have better interaction than with the standard Dialogs unit or Windows API, and will have your confirmation icon, just as expected.

Here is the result under a Windows Seven 64 bit computer:

And here is the same dialog created from our Emulated pure Delphi code:

Here is a selection task dialog, with "Command links" buttons, in native Seven:

And here is the window as created with the VCL emulation code:

Note that there is the confirmation icon. ;)

Working from Delphi 6 up to XE.

Herbertherbicide

Still, the programmer's interface looks easier to use than the interface of the VCL TTaskDialog. – Belvabelvedere

@Andreas Yes, the small footer icon is rendered using GDI: it's the standard dialog icon retrieved from the OS, stretched in its half size. I should use GDI+ to render it with better anti-aliasing. But I didn't want to add any further dependency to the unit, for the XP part. If you know how to retrieve a better looking half-sized icon through API, I'm your man! And yes, I tried to make the interface easier than TTaskDialog: it's not a free clone, it's a new implementation (I didn't look at VCL code, just wanted the work to be done). – Herbertherbicide

PS: I think the icon is looking not perfect, but acceptable. The user will understand its meaning. It's not like in the case of MessageDlg where the icon was totally wrong. – Willams

@Arnaud: LoadIconWithScaleDown seems to do it but it's available only where TaskDialogIndirect also is available (I wonder why? ;-)) - so it's of not much use for your emulation. – Seepage

You could solve the icon aliasing problem by using CreateIconFromSmallerIcon from here: #8113453 – Myo

Answer 3

if (Win32MajorVersion >= 6) and ThemeServices.ThemesEnabled then
    with TTaskDialog.Create(Self) do
      try
        Caption := 'Delete';
        Title := 'Are you sure to remove the minecraft?';
        Text := 'if you delete minecraft it well be gone forever.';
        CommonButtons := [tcbYes, tcbNo];
        CustomMainIcon.ReleaseHandle;
        CustomMainIcon.Handle := LoadIcon(0, IDI_QUESTION);
        Flags := [tfUseHiconMain];
        Execute;
      finally
        Free;
      end
  else
    MessageBox(Handle,
               'if you delete minecraft it well be gone forever.',
               'Are you sure to remove the minecraft?',
               MB_ICONQUESTION or MB_YESNO);

Lineberry

Welcome! You could make this question better in my estimation if you wrote a few sentences describing in words what you're trying to do and what your code does not do as you've written it. – Morganatic

Answer 4

if MessageDlg('Are You Want To Exit And Close All Form ? ', mtConfirmation, [mbYes, mbNo] , 0) = mrYes then
begin
Main_Form.Close;
end;

Orna

Your answer will be massively downvoted. – Willams