Missing $ on loop variable

Question

#!/usr/bin/perl
use strict;
use warnings;

my @array = qw[a b c];
foreach my($a,$b,$c) (@array) {
    print "$a , $b , $c\n";
}

I receive following error:

Missing $ on loop variable

What is wrong?

I am using: perl v5.10.1 (*) built for x86_64-linux-thread-multi

Acquit

Answer 1

I'm not aware that foreach can eat up more than one parameter at a time in Perl. I might be reading the documentation wrong.

Susceptive

This has changed since Perl v5.36. Iterate over multiple elements at the same time – Commutator

Answer 2

To grab multiple list items per iteration, use something like List::MoreUtils::natatime or use splice:

my @tmparray = @array; # don't trash original array
while ( my ($a,$b,$c) = splice(@tmparray,0,3) ) {
    print "$a , $b , $c\n";
}

Or reorganize your data into multiple arrays and use one of the Algorithm::Loops::MapCar* functions to loop over multiple arrays at once.

Awesome

does the first line creates a local copy of @array? – Acquit

@k0re : It depends on the scope how local the copy is. @tmparray is not local to the while loop only. – Markmarkdown

Answer 3

As mentioned in the other answers, Perl does not directly support iterating over multiple values in a for loop. This is one of the issues I addressed in my module List::Gen:

use List::Gen;

my @array = qw/a b c d e f/;

for (every 3 => @array) {
    print "@$_\n";
}

outputs:

a b c
d e f

Edit: The list slices that List::Gen produces are aliased to the original list, so that means you can change values in the slice to change the original list. That functionality does not seem possible with several of the other solutions posted for this question.

Emogene

Answer 4

Block::NamedVar provides nfor that DWIM. This is more convenient than the alternative ways to iterate.

use Block::NamedVar;

my @array = qw[a b c];
nfor my($a,$b,$c) (@array) {
    print "$a , $b , $c\n";
}

Stoop

Answer 5

I think you are missing the point of foreach loop. It goes through every value in an array. It handles one value at a time. Here's the correct code:

#!/usr/bin/perl
use strict;
use warnings;

my @array = qw[a b c];
foreach my $z (@array) {
    print "$z\n";
}

Valois

the thing is to access more than one value at a time. – Acquit

Answer 6

As of Perl version 5.36 released in 2022, you can iterate over multiple values at a time. For compatability with older versions, see @ysth's answer. https://perldoc.perl.org/perlsyn#Foreach-Loops

for my($a,$b,$c) (@array) { ... }
for my($key,$value) (%hash) { ... }
for my($key,$value) (%hash{sort keys %hash}) { ... } #sorted/consistent order

Bibliolatry

This is a stable feature in v5.40, but before that you need use experimental qw(for_list); to activate it. Iterate over multiple elements at the same time – Commutator