SPARQL: combine multiple predicate values into array of labels

SELECT ?propLabel ?val WHERE { BIND(wd:Q122426 as ?entity) { BIND(?entity AS ?valUrl) BIND("n/a" AS ?propUrl) BIND("name"@en AS ?propLabel) ?entity rdfs:label ?val. FILTER((LANG(?val)) = "en") # instance of } UNION { ?entity wdt:P31 ?valUrl . BIND("instance of"@en AS ?propLabel) # filter isIRI(?valUrl) ?valUrl rdfs:label ?valLabel FILTER (LANG(?valLabel) = "en") BIND(CONCAT(?valLabel) AS ?val) # occupation } UNION { ?entity wdt:P106 ?val. BIND("occupation"@en AS ?propLabel) # position held } UNION { ?entity wdt:P39 ?val. BIND("position"@en AS ?propLabel) # ... and more ... } }

# occupation } UNION { ?entity wdt:P106 ?valUrl. BIND("occupation"@en AS ?propLabel) ?valUrl rdfs:label ?valLabel FILTER (LANG(?valLabel) = "en") BIND(CONCAT(?valLabel) AS ?val)

But my question is

How can I 'collapse' the values for multiple predicates into a string? i.e. for the predicates P106, P119, Px, Py, etc. get:

| ?property | ?valueLabel | |-------------+-------------| | tags | politician, Giza East Field, something else, something else | | name | Henutsen |

Is there a more efficient way to structure the query rather than UNIONing every predicate? Like, supply just a list of predicates P31, P106, P39 etc

Here is a version that replaces the UNION with a compact VALUES clause, and use of the label service (courtesy of AKSW in the comments):

SELECT ?entity ?property ?valueLabel {
  VALUES ?entity { wd:Q122426 }
  VALUES (?p ?property) {
    (wdt:P31    "instance of"@en)
    (rdfs:label "name"@en)
    (wdt:P106   "occupation"@en)
    (wdt:P39    "position"@en)
  }
  ?entity ?p ?value
  FILTER (!isLiteral(?value) || lang(?value) = "" || langmatches(lang(?value), "en"))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Result:

| ?property   | ?valueLabel |
|-------------+-------------|
| instance of | human       |
| occupation  | politician  |
| name        | Henutsen    |

Collapsing the multiple rows into a single row, with comma-separated lists as values, is in theory also possible and would look something like this:

SELECT ?entity
  (group_concat(?property; separator=", ") AS ?properties)
  (group_concat(?valueLabel; separator=", ") AS ?values)
WHERE {
  ...
}
GROUP BY ?entity

with the original query inserted at .... The idea is to use GROUP BY to group the results by entity (not strictly necessary here as we only have a single entity anyway, but if you wanted to add more entities to the query), and then group_concat to combine all values per entity into one value.

Unfortunately, this doesn't work for some reason; ?properties looks fine but ?values is empty. It might have something to do with the “magic” label service, perhaps it is not compatible with aggregates.

Update: Here is a version that returns name and “tags” as separate rows, as in the updated question:

SELECT ?property ?valueLabel {
  {
    SELECT
      ("tags" AS ?property)
      (group_concat(?valueLabel; separator=", ") AS ?valueLabel)
    WHERE {
      VALUES ?p { wdt:P31 wdt:P106 wdt:P119 wdt:P39 }
      wd:Q122426 ?p ?value
      SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
    }
  } UNION {
    BIND ("name"@en AS ?property)
    wd:Q122426 rdfs:label ?valueLabel
    FILTER langMatches(lang(?valueLabel), "en")
  }
}

Results:

| ?property | ?valueLabel                        |
|-----------+------------------------------------|
| tags      | human, politician, Giza East Field |
| name      | Henutsen                           |

One thing is a little bit weird about this query. Note that ?valueLabel is assigned a value by the label service, but then re-assigned a different value in the SELECT clause of the inner sub-query. This kind of re-assignment is usually not allowed in SPARQL, but here it is actually required to make the query work. This seems to be a quirk with the label service.

But my question is

Recommended topics

Hot tags