How can I get content using XML::Twig?

Question

My aim is that start_tag_handler (see below) get the apps/title content when it finds an apps/title tag (see sample XML below).

And end_tag_handler gets the apps/logs content when it finds an apps/logs tag.

But instead this code returns null and exits.

This is the Perl code for parsing (using XML::Twig)###:

    #!/usr/local/bin/perl -w

    use XML::Twig;
    my $twig = XML::Twig->new(
                start_tag_handlers =>
                  { 'apps/title' => \&kicks
                  },
                twig_roots =>
                  { 'apps' => \&app
                  },
                end_tag_handlers =>
                  { 'apps/logs' => \&bye
                  }
                );
    $twig -> parsefile( "doc.xml");

    sub kicks {
        my ($twig, $elt) = @_;
        print "---kicks--- \n";
        print $elt -> text;
        print " \n";
    }

    sub app {
        my ($twig, $apps) = @_;
        print "---app--- \n";
        print $apps -> text;
        print " \n";
    }


    sub bye {
        my ($twig, $elt) = @_;
        print "bye \n";
        print $elt->text;
        print " \n";
    }

This is doc.xml###:

    <?xml version="1.0" encoding="UTF-8"?>
    <auto>
      <apps>
        <title>watch</title>
        <commands>set,start,00:00,alart,end</commands>
        <logs>csv</logs>
      </apps>
      <apps>
        <title>machine</title>
        <commands>down,select,vol_100,check,line,end</commands>
        <logs>dump</logs>
      </apps>
    </auto>

This is the output in the console###:

    C:\>perl parse.pl
    ---kicks---

    ---app---
    watchset,start,00:00,alart,endcsv
    ---kicks---

    ---app---
    machinedown,select,vol_100,check,line,enddump

Bachelor

Answer 1

Check out the XML::Twig documentation for start_tag_handlers:

The handlers are called with 2 params: the twig and the element. The element is empty at that point, its attributes are created though.

At the time start_tag_handlers is called, the text content isn't even seen yet, since parsing of the start tag (e.g. <title>, not the end tag </title>) has only just completed.

The reason that end_tag_handlers don't supply element text is probably for symmetry :-).

What you want is probably to use twig_handlers instead:

my $twig = XML::Twig->new(
    twig_handlers => {
        'apps/title' => \&kicks,
        'apps/logs' => \&bye
    },
    twig_roots => {
        'apps' => \&app
    },
);

Output is:

---kicks--- 
watch 
bye 
csv 
---app--- 
watchset,start,00:00,alart,endcsv
---kicks--- 
machine 
bye 
dump 
---app--- 
machinedown,select,vol_100,check,line,enddump

Supplementary

Thank you very much,I will try your idea then will comment more. And I misunderstand XML::Twig documentation,I thought start_tag_handlers knew it at that point... – Bachelor

twig_handlers are the usual way of calling handlers, start_tag_handlers should be used only when using twig_handlers is not possible (the element is potentially too big for example). end_tag_handlers should be used even less, as mentioned in the docs. – Incapacious

It was works ! Wow,author. I will do perusal.-> To mirod. Thanks a lot and little suprised by comment from author. – Bachelor