Configuring asciidoctor when using Spring Restdoc

Question

I'm adopting Spring Rest Docs and the test successfully created *.adoc files.

I made api-guide.doc file in src/docs/asciidoc directory to create html, but when I run asciidoc as a gradle task, it produces the following error.

Some problems were found with the configuration of task ':asciidoctor' (type 'AsciidoctorTask').
  - In plugin 'org.asciidoctor.convert' type 'org.asciidoctor.gradle.AsciidoctorTask' method 'asGemPath()' should not be annotated with: @Optional, @InputDirectory.

I initialized the project with spring initializer, so I believe there is no problem with gradle dependencies.

plugins {
    id 'org.springframework.boot' version '2.5.3'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'org.asciidoctor.convert' version '1.5.8'
    id 'java'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

ext {
    set('snippetsDir', file("build/generated-snippets"))
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-data-mongodb'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    compileOnly 'org.projectlombok:lombok'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    runtimeOnly 'com.h2database:h2'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'

}

test {
    outputs.dir snippetsDir
    useJUnitPlatform()
}

asciidoctor {
    inputs.dir snippetsDir
    dependsOn test
}

What could be the problem?

Iatrogenic

Answer 1

An update needs to be made to https://start.spring.io so that it generates configuration that's compatible with Gradle 7.

You could avoid the problem by downgrading to Gradle 6.x or you could switch to a more up-to-date version of the Asciidoctor Gradle plugin by replacing id 'org.asciidoctor.convert' version '1.5.8' with id 'org.asciidoctor.jvm.convert' version '3.3.2'

Tibbitts

Thanks! I resolved it by downgrading to gradle 6.9. – Iatrogenic