makeLenses for GADTs (Haskell)

Question

Is there an equivalent of makeLenses for GADTs? If I have a simple GADT like:

data D a b where
  D :: (Ord a, Ord b) => !a -> !b -> D a b

Is there a way to generate lenses automatically by passing in a constructor and a list of field names?

Gaggle

I have to ask: is it possible to write them by hand? – Reisinger

Answer 1

I don't think it can be done automatically, but writing some lenses by hand isn't that hard in this particular case:

{-# LANGUAGE GADTs #-}

import Control.Lens

data D a b where
  D :: (Ord a, Ord b) => !a -> !b -> D a b

field1 :: Lens' (D a b) a
field1 f (D x y) = fmap (\x' -> D x' y) (f x)

field2 :: Lens' (D a b) b
field2 f (D x y) = fmap (\y' -> D x y') (f y)

{- If you want type-changing lenses, you can also use these signatures.
 - Note that then the target type Ord constraint has to escape.

field1 :: (Ord a2) => Lens (D a1 b) (D a2 b) a1 a2
field2 :: (Ord b2) => Lens (D a b1) (D a b2) b1 b2
 -}

There seems to be a somewhat relevant GitHub issue, in which Kmett claims they cannot create lenses for existentially quantified fields.

Dogtired