Spock: Return input parameter in Stubs

Question

Given an method with a parameter in Java, e.g.

public class Foo {
   public Bar theBar(Bar bar) { /*... */ }   
}

When stubbing/ mocking foo, how do I tell it to accept any argument and return it? (Groovy)

def fooStub = Stub(Foo) {
  theBar(/*what to pass here*/) >> { x -> x }
}

As you can see I passed the identity function. However I do not know what to pass as argument. _ does not work because it is an ArrayList and thus not of type Bar

Digged

Do you have @CompileStatic or @TypeChecked on your spec? could you post your whole code, there is no reason why _ shouldn't work. – Dyl

Just ran into the same setup and situation. Trying to stub a Java class from Spock + Groovy and I only want to return the method's input, no more no less. Since I have no idea what's going on I simply leave my solution as a comment and I'd appreciate if someone could enlighten me. It seems the x input before the arrow is actually the entire arguments list of the method call? Doing the following solves the problem: theBar(_) >> { args -> args.get(0) }. But why is that necessary? How to express this correctly without any hacks? – Chessy

Answer 1

You can stub Foo class in following way:

Foo foo = Stub(Foo)
foo.theBar(_ as Bar) >> { Bar bar -> bar }

And here is full example:

import groovy.transform.Immutable
import spock.lang.Specification

class StubbingSpec extends Specification {

    def "stub that returns passed parameter"() {
        given:
        Foo foo = Stub(Foo)
        foo.theBar(_ as Bar) >> { Bar bar -> bar }

        when:
        def result = foo.theBar(new Bar(10))

        then:
        result.id == 10
    }

    static class Foo {
        Bar theBar(Bar bar) {
            return null
        }
    }

    @Immutable
    static class Bar {
        Integer id
    }
}

Audy

Did you try the same with Foo and Bar being Java classes? – Digged

@Digged Yes, it works exactly the same when Foo and Bar are Java classes, just tested this example and got same result. – Audy

Answer 2

I'm not sure what you mean. _ is the right thing to pass. Why do you think it is an ArrayList? It is of type Object and can be used for anything.

Shilohshim

That means that in Java, it has the wrong type (not Bar), right? – Digged

So? Spock is Groovy based, you cannot use Spock with Java. – Shilohshim