How can you automatically remove trailing whitespace in vim

Asked 10/12, 2008 at 14:2 Answered 8/9, 2021 at 9:9

Solved vim automation whitespace removing-whitespace

224

I am getting 'trailing whitespace' errors trying to commit some files in Git.

I want to remove these trailing whitespace characters automatically right before I save Python files.

Can you configure Vim to do this? If so, how?

Herzberg answered 10/12, 2008 at 14:2 Comment(3)

this doesn't concern python alone – Porcia 11/12, 2008 at 9:47

Use my DeleteTrailingWhitespace plugin. – Chronometer 22/6, 2012 at 7:21

Related: What's the simplest way to strip trailing whitespace from all lines in a file? at Vim SE – Bothy 19/2, 2015 at 13:7

226

I found the answer here.

Adding the following to my .vimrc file did the trick:

autocmd BufWritePre *.py :%s/\s\+$//e

The e flag at the end means that the command doesn't issue an error message if the search pattern fails. See :h :s_flags for more.

Herzberg answered 10/12, 2008 at 14:3 Comment(12)

Interesting! Trailing white space is a battle at work. I loathe it, others don't understand why. We use as much vi as vim (I use vim; they don't because they'd have to install it). I have a program I call stb to Strip Trailing Blanks and I use that as a filter; works in vi too. This is better. – Scibert 15/1, 2009 at 14:6

This changes cursor position on each save. Is is possible to avoid it? – Narcisanarcissism 24/10, 2009 at 15:59

OK, I've found, answer is below. – Narcisanarcissism 24/10, 2009 at 16:11

Since this is the de facto answer for this question maybe it should be updated to maintain cursor position. – Viscardi 4/5, 2011 at 14:26

see too keepjumps :h keepjumps – Compliant 31/8, 2011 at 22:3

You could upvote the better answer until it become the best first one presented. – Wan 8/12, 2011 at 15:32

This do changes the cursor position on each save, however, a simple gi will put you back on the previous cursor position. – Scoville 9/5, 2013 at 21:15

Using :%!sed -r 's/\s+$//' as the command seems to be another way (besides keepjumps) to prevent moving the cursor. See :h filter. – Tuantuareg 29/5, 2013 at 12:54

gi jumps to the last position where text was inserted (not always the cursor position before the :%s command) and :%!sed -r 's/\s+$//' jumps to the beginning of the file. I don't get how keepjumps is supposed to be used, :keepjumps :%s/\s+$//e doesn't seem to do anything different. I'm using :%s/\s\+$//e|normal '' and it seems to work as I expect (goes to the cursor position before using the :%s command). – Foliose 19/7, 2014 at 23:44

Correction for my previous comment: :%s/\s\+$//e|normal '' will jump to the wrong position if no trailing whitespaces were found. – Foliose 20/7, 2014 at 0:49

This will also delete trailing spaces in multi-line strings, which may not be desired in some cases. But I guess there is no easy way to avoid this? – Guffaw 11/8, 2015 at 8:58

Maybe you could explicit that the e at the end means, if we did not find the pattern, vi does not consider the substitute command as failed – Zonda 1/12, 2016 at 12:46

183

Compilation of above plus saving cursor position:

function! <SID>StripTrailingWhitespaces()
  if !&binary && &filetype != 'diff'
    let l:save = winsaveview()
    keeppatterns %s/\s\+$//e
    call winrestview(l:save)
  endif
endfun

autocmd FileType c,cpp,java,php,ruby,python autocmd BufWritePre <buffer> :call <SID>StripTrailingWhitespaces()

If you want to apply this on save to any file, leave out the second autocmd and use a wildcard *:

autocmd BufWritePre,FileWritePre,FileAppendPre,FilterWritePre *
  \ :call <SID>StripTrailingWhitespaces()

Narcisanarcissism answered 24/10, 2009 at 16:10 Comment(12)

You could better your function by also saving the last search and restoring it. let _s=@/ let @/=_s – Yakut 21/6, 2011 at 14:58

For other noobs like me this is how you limit the files the function is called on: – Maroon 17/5, 2012 at 22:28

Pure awesome. I use vim but am too lazy to look stuff up like this usually. This gave me a way to automate applying my arsenal of regexes on save. I'm stuck using Ruby for now, so I love not having to cut & paste my hash-rocket-killing regex.:wa – Royroyal 10/6, 2013 at 18:30

I removed the autocmd FileType c,cpp,java,php,ruby,python part to make it apply to all files. – Barrettbarrette 29/8, 2013 at 18:50

I can't figure out why col(".") always returns 1 for me. – Unkennel 1/11, 2013 at 14:43

I had to add *. before each file extension. – Halleyhalli 3/12, 2013 at 15:18

@xApple: Inside functions, saving and restoring the last search is not necessary - leaving the function context will take care of that. – Rhomb 25/2, 2014 at 13:16

@Barrettbarrette you need to also replace <buffer> with * if you want it to work on all files – Bolshevist 19/5, 2014 at 1:32

Is there any good reason to only limit this to certain file types? – Georgettegeorgi 20/1, 2015 at 7:21

If you prefix the substitute command w/ keepp, it will not alter your search history, i.e. keepp %s/\s\+$//e – Cortex 23/7, 2016 at 4:55

Add an undojoin to stop this from polluting your undo history: autocmd BufWritePre * undojoin | :call <SID>StripTrailingWhitespaces() – Golda 27/4, 2020 at 10:23

Add \m to the pattern to be independent of the magic option. Save position better with let l:save = winsaveview() and call winrestview(l:save). Add if !&binary && &filetype != 'diff' to ignore on binary and diff files (E.g. patch file to remove white spaces). – Pow 6/1, 2021 at 10:0

I also usually have a :

match Todo /\s\+$/

in my .vimrc file, so that end of line whitespace are hilighted.

Todo being a syntax hilighting group-name that is used for hilighting keywords like TODO, FIXME or XXX. It has an annoyingly ugly yellowish background color, and I find it's the best to hilight things you don't want in your code :-)

Jumbala answered 10/12, 2008 at 14:23 Comment(4)

Or you can set list and set listchars+=trail:. – Nones 11/12, 2008 at 7:17

Excellent - it's the perfect middle ground between automatically removing trailing whitespace (even when I may not be aware of it, or when it's someone else's code that I'm just happening to work in the same file with), to not doing anything about it. Thanks. – Aerometeorograph 22/6, 2011 at 7:13

unfortunately, my favorite color scheme zenburn doens't highlight – Ucayali 22/7, 2011 at 8:14

@PeterLong, doesn't work in railscasts theme either. Check it with :hi Todo. So I perused :hi <Tab> and :help hi. I considered Cursor and Error, but I think I'll try match VisualNOS /\s\+$/ . I might combine this with some of the autocmds from other answers here. – Hatch 26/7, 2014 at 22:16

I both highlight existing trailing whitespace and also strip trailing whitespace.

I configure my editor (vim) to show white space at the end, e.g.

enter image description here

with this at the bottom of my .vimrc:

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

and I 'auto-strip' it from files when saving them, in my case *.rb for ruby files, again in my ~/.vimrc

function! TrimWhiteSpace()
    %s/\s\+$//e
endfunction
autocmd BufWritePre     *.rb :call TrimWhiteSpace()

Paradis answered 10/12, 2012 at 5:6 Comment(1)

Great! Thanks!, I specially like the function. – Saccharide 15/9, 2020 at 20:49

Here's a way to filter by more than one FileType.

autocmd FileType c,cpp,python,ruby,java autocmd BufWritePre <buffer> :%s/\s\+$//e

Mawson answered 13/1, 2012 at 21:22 Comment(1)

Every File: autocmd FileType * autocmd BufWritePre <buffer> :%s/\s\+$//e – Sticktight 9/3, 2017 at 23:19

I saw this solution in a comment at VIM Wikia - Remove unwanted spaces

I really liked it. Adds a . on the unwanted white spaces.

Put this in your `.vimrc`

" Removes trailing spaces
function TrimWhiteSpace()
  %s/\s*$//
  ''
endfunction

set list listchars=trail:.,extends:>
autocmd FileWritePre * call TrimWhiteSpace()
autocmd FileAppendPre * call TrimWhiteSpace()
autocmd FilterWritePre * call TrimWhiteSpace()
autocmd BufWritePre * call TrimWhiteSpace()

Selden answered 13/3, 2017 at 6:31 Comment(0)

Copied and pasted from http://blog.kamil.dworakowski.name/2009/09/unobtrusive-highlighting-of-trailing.html (the link no longer works, but the bit you need is below)

"This has the advantage of not highlighting each space you type at the end of the line, only when you open a file or leave insert mode. Very neat."

highlight ExtraWhitespace ctermbg=red guibg=red
au ColorScheme * highlight ExtraWhitespace guibg=red
au BufEnter * match ExtraWhitespace /\s\+$/
au InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
au InsertLeave * match ExtraWhiteSpace /\s\+$/

Tanagra answered 31/8, 2011 at 10:33 Comment(2)

The blog link seems to have died. – Rhomb 25/2, 2014 at 13:18

The same solution is found at the this link under "Using the match command". – Orelee 2/8, 2019 at 9:7

This is how I'm doing it. I can't remember where I stole it from tbh.

autocmd BufWritePre * :call <SID>StripWhite()
fun! <SID>StripWhite()
    %s/[ \t]\+$//ge
    %s!^\( \+\)\t!\=StrRepeat("\t", 1 + strlen(submatch(1)) / 8)!ge
endfun

Passably answered 11/12, 2008 at 23:20 Comment(5)

Hum, that's pretty dangerous to do it on "*" if you eventually open up binary files, they may end up in a pretty bad shape. – Jumbala 18/12, 2008 at 20:45

Yeah probably not the smartest, then again I don't use vim for a hex editor either. That won't execute unless you save. – Passably 1/4, 2009 at 20:43

I think this beats the alternative of listing every single file type that you might work on, no? I work on rb, php, cs, html, sass, css, js, coffee, xml, xslt, pl, etc, etc, etc... Is there a happy medium? – Policlinic 18/6, 2011 at 1:27

Unless you're writing to binary files in vim this probably won't ever be a issue. – Passably 20/6, 2011 at 21:47

It appears in the first %s the global (g) flag is as useless as a space at EOL :-) – Aliform 6/2, 2013 at 15:41

A solution which simply strips trailing whitespace from the file is not acceptable in all circumstances. It will work in a project which has had this policy from the start, and so there are no such whitespace that you did not just add yourself in your upcoming commit.

Suppose you wish merely not to add new instances of trailing whitespace, without affecting existing whitespace in lines that you didn't edit, in order to keep your commit free of changes which are irrelevant to your work.

In that case, with git, you can can use a script like this:

#!/bin/sh

set -e # bail on errors

git stash save commit-cleanup
git stash show -p | sed '/^\+/s/ *$//' | git apply
git stash drop

That is to say, we stash the changes, and then filter all the + lines in the diff to remove their trailing whitespace as we re-apply the change to the working directory. If this command pipe is successful, we drop the stash.

Whomsoever answered 16/3, 2014 at 17:30 Comment(0)

For people who want to run it for specific file types (FileTypes are not always reliable):

autocmd BufWritePre *.c,*.cpp,*.cc,*.h,*.hpp,*.py,*.m,*.mm :%s/\s\+$//e

Or with vim7:

autocmd BufWritePre *.{c,cpp,cc,h,hpp,py,m,mm} :%s/\s\+$//e

Callipygian answered 11/8, 2016 at 18:34 Comment(0)

The other approaches here somehow didn't work for me in MacVim when used in the .vimrc file. So here's one that does and highlights trailing spaces:

set encoding=utf-8
set listchars=trail:·
set list

Haply answered 10/10, 2014 at 12:53 Comment(2)

Executing set listchars=trail:· saying: E474: Invalid argument: listchars=trail:·. Can you validate your example? – Bothy 16/2, 2015 at 14:16

@Bothy see #18322038 – Haply 16/2, 2015 at 14:35

If you trim whitespace, you should only do it on files that are already clean. "When in Rome...". This is good etiquette when working on codebases where spurious changes are unwelcome.

This function detects trailing whitespace and turns on trimming only if it was already clean.

The credit for this idea goes to a gem of a comment here: https://github.com/atom/whitespace/issues/10 (longest bug ticket comment stream ever)

autocmd BufNewFile,BufRead *.test call KarlDetectWhitespace()

fun! KarlDetectWhitespace()
python << endpython
import vim
nr_unclean = 0
for line in vim.current.buffer:
    if line.rstrip() != line:
        nr_unclean += 1

print "Unclean Lines: %d" % nr_unclean
print "Name: %s" % vim.current.buffer.name
cmd = "autocmd BufWritePre <buffer> call KarlStripTrailingWhitespace()"
if nr_unclean == 0:
    print "Enabling Whitespace Trimming on Save"
    vim.command(cmd)
else:
    print "Whitespace Trimming Disabled"
endpython
endfun

fun! KarlStripTrailingWhitespace()
    let l = line(".")
    let c = col(".")
    %s/\s\+$//e
    call cursor(l, c)
endfun

Ottilie answered 29/9, 2016 at 20:50 Comment(1)

You could also keep search register let _s=@/ and restore it at the end ` let @/=_s` .In this case we are using black hole register – Compliant 23/11, 2016 at 13:2

autocmd BufWritePre *.py execute 'norm m`' | %s/\s\+$//e | norm g``

This will keep the cursor in the same position as it was just before saving

Ditchwater answered 8/9, 2021 at 9:9 Comment(0)

autocmd BufWritePre * :%s/\s\+$//<CR>:let @/=''<CR>

Appanage answered 1/6, 2015 at 16:37 Comment(0)

Hot tags

Godot Unity Godot Help Programming Godot 4.X GUI GDScript 3D 2D Physics CSharp Godot 3.X VR XR Projects C++

Put this in your .vimrc

Recommended topics

Hot tags

Put this in your `.vimrc`